윈 도 우 VHDman.exe으로 VHD 교차부팅 테스트

네, 안녕하세요

방금 실컴에서 테스트해보니까 GPT 체크해도 이상없이 잘 작동합니다

예전에도 GPT 체크해서 이상이 없었습니다.

아무래도 PE 버전에 따라서 다른 건지...다른 PE로 해봐야겠습니다

그런데 제가 가진 몇가지 PE에서 해봐도 GPT 체크하면 에러가 발생하네요..

먼저 실컴 윈도에서 gpt 형식으로 VHD는 잘 만들어집니다

PE에서는 이렇게 실패하네요

제가 예전에 만든 PE로도 한번 해봤는데 마찬가지로 실패하네요

gpt 체크해제하면 잘 만들어집니다

제가 주로 PE가 아닌 실컴에서만 VHDman.exe과 RSImageX를 사용하고, 특히 GPT로 VHD를 잘 만들지 않아서 아직까지 모르고 있었네요

다른 유명하신 분의 PE를 한번....사실 본문의 PE도 유명하신 분의 PE입니다만;; 다른 분들 PE도 한번 테스트해봐야겠습니다

어떤 분이 가장 유명하신지...? (혼자 생각중입니다) // 어쩌면 가상머신의 상황이 문제가 되는건지..그러면 실컴으로 PE 부팅을 해봐야겠네요

13일간 리부팅하지 않고 버티고 있었는데요. 오랜만에 산책을 하겠네요 ^^

-----------------------

실컴에서 PE 부팅을 해도 마찬가지 현상입니다. 실컴까지 특이한 상황인지는 모르겠네요

gpt 체크해제만 하면 잘 만들어집니다

또 다른 유명하신 분의 PE도 같은 현상입니다

역시 gpt 체크해제하면 잘 만들어집니다

제가 가진 pe에서 테스트 해보니 같은 에러가 생기네요.

실컴에서 실행하면 convert gpt실행시 msr파티션이 생겨서 이걸 삭제하는 코딩을 넣어뒀는데 pe에서 실행해보니 msr파티션이 생기질 않네요.

삭제할 파티션이 없으니 에러가 생기면서 진행이 안되더군요.

실컴과 pe가 왜 다른지 참..

어떻게 수정해야 할지 고민이 됩니다.

msr파티션을 그대로 두면 vhdman에서의 작업이 주로 파티션 1을 선택해서 하는건데 원하는 파티션이 선택안되고 msr판티션이 선택돼서 작업이 되는 경우가 생길 수도 있고 해서요

마침 지금 댓글 달려고 했는데 오셨네요

알고 보니까 저도 1달전쯤에 어떤 테스트하면서 bat 파일 만들 때 gpt로 변환하는 것을 했습니다

그리고 그 때 실컴에서는 gpt로 변환하자마자 msr 예약 파티션이 생겨서 삭제하는 명령을 넣었고

PE에서는 gpt로 변환해도 msr이 생기지 않아서 삭제하지 않도록 했습니다.

실컴과 PE를 구분하지 않고 그냥 에러가 생기면 다르게 처리되도록 했습니다

bat 파일의 일부입니다. 그 때 bat 파일에 주석까지 달아났네요 ㅎㅎ;

 >"%tmp%\diskpart.tmp" echo Select disk %disk%

>>"%tmp%\diskpart.tmp" echo clean

>>"%tmp%\diskpart.tmp" echo convert GPT

>>"%tmp%\diskpart.tmp" echo sel par 1 

diskpart /s "%tmp%\diskpart.tmp" || goto :not_msr

 >"%tmp%\diskpart.tmp" echo Select disk %disk%

>>"%tmp%\diskpart.tmp" echo sel par 1 

>>"%tmp%\diskpart.tmp" echo del par override

:: 실컴에서는 GPT로 만들자마자 자동으로 msr 예약 파티션이 생기는 윈도가 있어서 삭제함. PE에서는 생기지 않음

:cre_par

>>"%tmp%\diskpart.tmp" echo CREATE PARTITION EFI SIZE=100

>>"%tmp%\diskpart.tmp" echo format quick fs=fat32 label="System" 

>>"%tmp%\diskpart.tmp" echo assign letter="Z" 

...

...

:not_msr

 >"%tmp%\diskpart.tmp" echo Select disk %disk%

@goto :cre_par

1번째 파티션 선택했을 때 msr 파티션이 없어서 에러가 생긴다는 점을 이용하여 위와 같이 만들었습니다

diskpart /s "%tmp%\diskpart.tmp" || goto :not_msr

제가 배치 파일은 잘 몰라서요.  여기서 || 의 의미가 뭔지요?  

위 배치파일을 보니 efi파티션을 만드시는것 같은데 그걸 만들 필요가 있을까요? 어차피 부팅은 실컴의 efi파티션에서 할테니까요

네, || 는 오류가 생긴 것을 의미합니다. 반대로 &&는 성공한 경우를 의미합니다

제가 1달 전에 테스트한 것은 UEFI 부팅에 필요한 실컴 파티션을 만드는 것이라서 efi 파티션부터 만들었습니다

VHD 부팅과는 관련이 없는 그냥 GPT 디스크를 만드는 것이었습니다

혹시나 하는 노파심에 씁니다

위에 > 1개와 >> 2개를 주의하셔야 됩니다. 전부 > 1개나 >> 2개로 하시면 문제가 생깁니다

> 1개는 시작할 때만 사용합니다. >> 2개는 계속 추가하는 것입니다.

참고로, 위에 명령어들은 1달 전에 테스트했을 때 제대로 작동하는걸 확인한 것입니다.

msr 예약파티션이 생기든지, 생기지 않든지 제대로 작동했습니다

방금 다시 확인해봤습니다

PE에서는 gpt로 변환했을 때 msr이 생기지 않아서 1번째 파티션을 선택하면 오류가 발생합니다

그래서 1번째 파티션 삭제없이 바로 파티션 만들기를 진행합니다

윈도에서는 msr이 생기기 때문에 1번째 파티션을 선택했을 때 오류가 생기지 않습니다

제가 테스트한 것이 VHD가 아니고 일반 디스크라서 다를 수 있다고 생각하실 듯 하여 VHD를 대상으로 테스트해봤습니다

결국은 같았습니다. VHD를 만드는 것만 앞에 추가되었습니다

실컴 윈도에서 실행한 것입니다

다음은 PE에서 실행한 것입니다. 

일반 디스크와 VHD가 gpt로 만들 때 같았습니다

참고로 올립니다. 위에 bat 파일을 좀 더 수정했습니다

clean을 방금 만든 vhd라서 필요없어서 제외하고, 디스크를 찾는 방식을 언어와 관계없이 찾을 수 있게 했습니다

그 외에는 디스크 상태가 어떤지 보기용으로 추가했습니다

@prompt $s

@color 1f

@cd /d %~dp0

@title VHD를 GPT 디스크로 만들기

@mode con cols=200 lines=1000

@setlocal enabledelayedexpansion

@if /i "%SystemDrive%"=="X:" goto :disk

@echo 관리자권한 확인용 >%windir%\admin.confirm || @(

echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\admin.vbs"

echo UAC.ShellExecute "%~0", "", "", "runas", 1 >> "%temp%\admin.vbs"

wscript.exe "%temp%\admin.vbs" & del "%temp%\admin.vbs" & exit)

@del %windir%\admin.confirm

:disk

cls

@echo.

@echo.

@echo.================================================

@echo. VHD를 GPT 디스크로 만듭니다 - 10GB

@echo.================================================

@echo.     

@pause

echo lis dis | diskpart 

@echo.

  >"%tmp%\diskpart.tmp" echo create vdisk file="%~dp0Test.vhd" maximum=10240 type=expandable

>>"%tmp%\diskpart.tmp" echo attach vdisk

diskpart /s "%tmp%\diskpart.tmp" || @(

@echo.

@echo.

@echo.================================================

@echo. diskpart 작업에 오류가 발생했습니다

@echo.================================================

@echo.     

@pause

@exit

)

echo lis dis | diskpart > "%tmp%\diskpart.tmp"

@type "%tmp%\diskpart.tmp"

@echo.

for /f "tokens=2 delims=* " %%a in ('"type "%tmp%\diskpart.tmp""') do @set disk=%%a

:: 언어와 관계없이 disk 번호를 찾게 했습니다

 >"%tmp%\diskpart.tmp" echo Select disk %disk%

:: 이 자리에 있던 clean은 방금 만든 vhd라서 필요 없기 때문에 제외했습니다

>>"%tmp%\diskpart.tmp" echo convert GPT

>>"%tmp%\diskpart.tmp" echo sel par 1 

set error=0

diskpart /s "%tmp%\diskpart.tmp" || set error=1

 >"%tmp%\diskpart.tmp" echo Select disk %disk%

if %error%==1 goto :cre_par

>>"%tmp%\diskpart.tmp" echo sel par 1 

>>"%tmp%\diskpart.tmp" echo del par override

:: 윈도우에서는 diskpart로 GPT 디스크로 변환하자마자 자동으로 msr 예약 파티션이 생겨서 삭제합니다. PE에서는 생기지 않습니다

:cre_par

>>"%tmp%\diskpart.tmp" echo cre par pri

>>"%tmp%\diskpart.tmp" echo format quick fs=ntfs override

>>"%tmp%\diskpart.tmp" echo assign letter="W" 

>>"%tmp%\diskpart.tmp" echo lis dis

>>"%tmp%\diskpart.tmp" echo lis par

diskpart /s "%tmp%\diskpart.tmp"

@del /f/a/q "%tmp%\diskpart.tmp"

@echo.

@echo.

@echo.=====================================================

@echo. 모든 작업을 완료했습니다

@echo.=====================================================

@echo.     

@pause

@exit

이건 윈도우에서 실행한 것이고 다음은 PE에서 실행한 것입니다

위 pe는 작업에는 관계없습니다만, 조금 특이하게 %tmp% 변수가 윈도우 폴더로 되어 있더군요. 

배치파일이 아니라 번거롭지만 가끔씩 기본부팅을 변경시에는 자식파일중 아무 파일이나 하나 선택후 교차부팅 버튼 위의 clean자식부팅을 클릭하면 다음 부팅시엔 다른 자식으로 부팅이 됩니다.

본문에 쓰려다가 혹시 제가 사용하던 것과 다를 수도 있다는 생각에 말았는데요. 방금 해보니까 제가 하던대로 됩니다

자동 교차 부팅은 강제적인 것은 아닙니다

부팅 때 자동 선택된 메뉴와 반대로 기존에 부팅하시던 자식 VHD를 선택하여 부팅하시면 계속 사용하시던대로 유지가 됩니다

필요시에만 자동 선택된 메뉴를 선택하시면 초기화가 됩니다. 따라서 bat 파일은 필요하지 않을 듯 합니다