윈 도 우 특정파일을 제외하고 폴더와 파일 모두 삭제하고 싶습니다...

단순 for %%i in (*.*) do if not "%%i"=="*.bat" del "%%i 하나로 가능하다면 좋겠습니다

파일은 최소 단위 입니다.

파일은 그나마 bat가 아니면 삭제 가능하지만

폴더는 그렇지 않습니다.

폴더속에는 수 많은 폴더가 있습니다 또 폴더속에도 폴더가 있으며 그 폴더 속에도 또 폴더가 있습니다

가령)

     a>b>c>d>e>f 5계층으로 이루어져 있는 폴더가 있다면

1. 한 폴더에는 몇개의 폴더가 존재 하는지 구해야 할것입니다.

2. 폴더속에 bat 아닌것만 삭제 조건

3. 폴더속에 파일이 없다면 삭제(단 폴더속 폴더가 있는경우 별도 조건)

f폴더에 아무것도 없다면 f폴더는 삭제 가능

d폴더를 지우기 위해 e폴더, f폴더 부터 해결해야 d폴더를 지울수 있는 조건이 나올겁니다

rmdir은 조건을 따지지 않으므로 다른 많은 스크립트 명령을 동원해야 가능할것입니다.

뭔가 시험 문제 같은 느낌인데요;;

bat 파일을 제외하고 파일부터 삭제한 후에 폴더 내부에 bat 파일 유무로 폴더를 삭제하도록 하니까 비교적 쉽게 되었습니다

테스트한 bat 파일은 위험성이 있어서 공개하지 않고, bat 파일 내용만 올립니다. H:을 D:으로 2군데 수정하시면 됩니다

데이터용 드라이브는 위험하기 때문에 없어도 되는 XP 윈도를 대상으로 삭제 테스트했습니다. XP 백업부터하고 반복 테스트했습니다

@prompt $s
@color 1f
@cd /d %~dp0
@title bat 파일만 제외하고 모든파일과 폴더 삭제하기
@mode con cols=200 lines=1000
@setlocal enabledelayedexpansion

@echo 관리자권한 확인용 >%windir%\admin.confirm || @(
echo Set UAC = CreateObject^("Shell.Application"^) > "%tmp%\admin.vbs"
echo UAC.ShellExecute "%~0", "", "", "runas", 1 >> "%tmp%\admin.vbs"
"%tmp%\admin.vbs" & del "%tmp%\admin.vbs" & exit)
@del %windir%\admin.confirm

@echo.
@echo.
@echo.=========================================================================
@echo. 삭제 테스트용입니다
@echo.=========================================================================
@echo.     
@pause

for /f "tokens=*" %%a in ('dir /a-d /b /s H:\ 2^>nul') do @if /i not "%%~xa"==".bat" del /f/a/q "%%a"
for /f "tokens=*" %%a in ('dir /ad /b /s H:\ 2^>nul') do (
@set /a k=0
for /f "tokens=*" %%b in ('dir /a-d /b /s "%%a\*.bat" 2^>nul') do @(
set /a k+=1
)
if !k!==0 rd /q/s "%%a"
@echo.
@echo.================================================================================================================================
@echo. "%%a" 폴더 안에 포함된 총 bat 파일 갯수는 !k!개 입니다
@echo.================================================================================================================================
)

@echo.
@echo.
@echo.====================================
@echo. 모든 작업을 완료했습니다
@echo.====================================
@echo.     
@pause
@exit

ㄴ 참고로, 지정된 경로를 찾을 수 없다는 것은 이미 상위 폴더가 검색되어서 삭제되어 버려서 그렇습니다

삭제되어 버린 후에도 처음 검색된대로 bat 파일은 진행하기 때문에 이런 현상이 발생합니다. bat 파일에서는 흔한 일로 오류는 아닙니다.

XP의 Windows 폴더 안에도 원래 bat 파일이 숨어 있더군요. 이번 기회에 발견한 새로운 사실이네요.

이건 테스트용으로 넣은 빈 bat 파일입니다