윈 도 우 배치파일 관리자 계정으로 실행하는 방법들

안녕하세요? 오늘 질문글이 있어서 정리해봅니다.^^ 일부는 뇌피셜일 수 있으니 오류나면 알려주세요~.

- https://windowsforum.kr/qna/17671483

질문에 대해 검색하다 다음 링크를 발견하였습니다.ㅡ,.ㅡ

- https://developpaper.com/how-to-make-bat-batch-run-with-administrators-permission/

 

필요시 배치파일을 관리자 권한으로 실행하는 방법인데, 더 효율적인 방법이 있으시면 댓글로 올려주시면 좋겠습니다.

 

우선 배치 파일을 마우스 우클릭하여 "관리자 권한으로 실행" 하는 방법이 수월하죠.^^

 

배치파일을 직접실행시 배치파일 내에서 관리자 권한으로 실행된 것인지를 검사하여 

관리자 권한 실행이 아니면 배치파일 자신을 관리자 권한으로 재 실행하는 것입니다.(UAC 화면을 만날 수 있겠습니다.)

1. 배치 코드 중 "명령어(관리자 권한으로만 실행되는) || 오류시 실행(자신을 관리자 권한으로 재실행)" 형태를 이용

2. argument에 특정 키워드를 사용하는... bypass token?으로 사용하는 방법이 있는데 여기서는 1번으로...

 

 

가. 우선 관리자 권한으로 실행된 것인지를 체크하는 방법은 다음과 같은 것들이 있습니다.

(관리자 권한이 아니면 모두 오류를 발생합니다. 시스템에 영향을 주지 않는 명령어들로 구성하면 좋겠죠.)

- 참고; https://docs.microsoft.com/ko-kr/windows/security/identity-protection/access-control/security-identifiers

 

net session

reg query HKU\S-1-5-19

reg query HKU\S-1-5-20

fsutil dirty query %systemdrive%

bcdedit

 

 

나. 관리자 권한으로 실행하는 명령어들 ; %0 또는 %~s0 는 상황에 맞게 선택하시면 될 것 같습니다.

- 참고; https://ss64.com/nt/syntax-args.html

 

PowerShell start -verb runas "%~s0 %*"

mshta vbscript:createobject("shell.application").shellexecute("%~s0","%*","","runas",1)(window.close)

mshta vbscript:close(createobject("shell.application").shellexecute("%~s0","%*","","runas",1))

mshta "javascript:close(new ActiveXObject('shell.application').ShellExecute('%~nx0', '%*', '', 'runas', 1))"

nircmd elevate "%~s0 %*"

- http://nircmd.nirsoft.net/elevate.html

Elevate "%~s0 %*"

- https://jpassing.com/2007/12/08/launch-elevated-processes-from-the-command-line/

또 GUI겸용 nirsoft의 AdvancedRun.exe, Sordum의 PowerRun, M2Team의 Nsudo 등으로 가능할 것 같습니다.

 

 

다. (가,나)를 조합한 예제

- 관리자 권한 체크 명령어에 리다이렉션하여 메시지를 감추기 접미어; 1>nul 2>nul 또는 1>nul 2>&1 또는 >nul 2>&1 등

- 참고; https://ss64.com/nt/syntax-redirection.html

 

다-1. 파워쉘 이용

@echo off

reg query HKU\S-1-5-20 >nul 2>&1 || (PowerShell Start -verb runas '%0' '%*' & exit)

::실행코드

pause & exit /b

 

@echo off

net session 1>nul 2>nul || (PowerShell Start -verb runas '%0' '%*' & exit)

::실행코드

pause & exit /b

 

다-2. mshta.exe with VBScript/Javascript 이용

@echo off

net session >nul 2>&1 || (call :RunAsAdmin "%~s0" "%*" & exit)

::실행코드

pause & exit /b

:RunAsAdmin

mshta vbscript:createobject("shell.application").shellexecute("%~1","%~2","","runas",1)(window.close)

goto:eof

 

어제는 계속 오류를 뿜어서 위처럼 서브프로시져로 처리했는데, 아침에 & 하나 더 붙였더니 성공했습니다. vbs로는 이걸로...^^

@echo off

net session >nul 2>&1 || mshta vbscript:createobject("shell.application").shellexecute("%~s0","%*","","runas",1)(window.close) && exit

::실행코드

pause & exit /b

 

몇 자라도 길이를 더 줄이면 다음처럼도 가능하네요.^^;

@echo off

net session >nul 2>&1 || mshta vbscript:close(createobject("shell.application").shellexecute("%~s0","%*","","runas",1)) && exit

::실행코드

pause & exit /b

 

댓글에 와로님께서 자바스크립트 예제를 올려주셔서 몇번의 간소화 테스트를 걸려 아래처럼 추가합니다.^^;

- 처음 검토시 javascript 내 backslash 처리 문제가 있어서 패스한 내용입니다.

- cd /d "%~dp0" 로 스크립트 폴더로 이동후 %~nx0 로 실행해야한다는... 코드를 좀 더 길게하면 해결할 수는 있겠지만요. 

@echo off & cd /d "%~dp0"

net session >nul 2>&1 || mshta "javascript:close(new ActiveXObject('shell.application').ShellExecute('%~nx0', '%*', '', 'runas', 1))" && exit

::실행코드

pause & exit /b

 

다-3. 추가로 응용하면 이런 것도 가능한 것 같습니다.

whoami /all|findstr S-1-16-12288 >nul 2>&1||(PowerShell start -verb runas '%~s0 %*'&exit)

 

 

 

밤이 깊었습니다. 편히 주무십시오. -꾸~벅-

---

 

PE 등에서 .net이 없어서 powershell을 사용할 수 없고 vbs는 사용할 수 있다면 다음도 가능할 것 같습니다.

 

bcdedit>nul||(echo Set x=CreateObject^("Shell.Application"^):x.ShellExecute "%~0",,,"runas">"%tmp%\x.vbs"&"%tmp%\x.vbs"&del "%tmp%\x.vbs"&exit)

 

유니코드 vbs 생성

bcdedit>nul||(cmd/u/c echo Set U=CreateObject^("Shell.Application"^): U.ShellExecute "%~fs0",,,"runas">"%tmp%\U.vbs")&"%tmp%\U.vbs"&del "%tmp%\U.vbs"&exit