강좌 / 팁

소프트웨어 Total commander 에서 검색된 파일들을 폴더 구조와 함께 복사하기 내용추가

2021.03.22 18:49

줄리아니 조회:1208 추천:6

 

https://windowsforum.kr/lecture/12260427 지후빠님께서 아주 잘 설명해 주셨는데요

 

Autohotkey를 이용하여 만들어 보았습니다 

 

사용법은 프로그램 실행후 Total commander 에서 파일을 선택후에 Ctrl+Alt+C 누르시면 반대패널에 폴더구조가 복사됩니다 

 

소스파일과 실행 파일 첨부합니다 

 

 

image.png

 

#SingleInstance force
#Persistent
 
Menu, MyMenu, Add, Copy to &Target Create Folder, Item1
Menu, MyMenu, Add, Copy to &Source Create Folder, Item2
Menu, MyMenu, Add 
Menu, MyMenu, Add, Move to Target Create Folder , Item3
Menu, MyMenu, Add, Move to Source Create Folder , Item4
Menu, MyMenu, Add 
Menu, MyMenu, Add, Copy to Target With &Folder Structure , Item5
 
^k:: ;Menu hotkey
 
IfWinActive, ahk_class TTOTAL_CMD
{
    
    ControlGetFocus, Control, ahk_class TTOTAL_CMD
    If (Control="TMyListBox1" or Control="TMyListBox2" or Control="LCLListBox1" or Control="LCLListBox2")
    {
        Temp:=Clipboard        
        SendMessage 1075, 2030, , , ahk_class TTOTAL_CMD  ; Copy Target path to clipboard
        Target:=clipboard
        SendMessage 1075, 2018, , , ahk_class TTOTAL_CMD ; Copy filenames to clipboard
        FullPathName:=clipboard
        Clipboard:=Temp
        Menu, MyMenu, Show ,650,400
    }
}
 
Return
 
Item1: ;타켓 폴더 만들고 복사
Loop, Parse, FullPathName, `n, `r
{
    Folder:=RegExMatch(A_LoopField,"^(.+\\)$",File_Path) ;  파일 or 폴더 판별 
 
    if Folder=1
    continue
        
    RegExMatch(A_LoopField,"^(.+\\)(.+)\.",File_Path) ; 파일 이름 알아내기
    Tpath:=Target . "\" . File_Path2
    FileCreateDir , %Tpath%     
    FileCopy, %A_LoopField%, %Tpath%  
}
return
 
Item2: ;소스 폴더 만들고 복사
 
Loop, Parse, FullPathName, `n, `r
{
    Folder:=RegExMatch(A_LoopField,"^(.+\\)$",File_Path) ; 파일 or 폴더 유무 판별 
    
    if Folder=1
    continue    
   
    RegExMatch(A_LoopField,"^(.+\\)(.+)\.",File_Path) ; 파일 이름 알아내기
    Tpath:=File_Path1 . "\" . File_Path2    
    FileCreateDir , %Tpath%     
    FileCopy, %A_LoopField%, %Tpath% 
}
return
 
Item3: ;타켓으로 폴더 만들고 파일 이동
 
Loop, Parse, FullPathName, `n, `r
{
    Folder:=RegExMatch(A_LoopField,"^(.+\\)$",File_Path) ;  파일 or 폴더 판별 
 
    if Folder=1
    continue
        
    RegExMatch(A_LoopField,"^(.+\\)(.+)\.",File_Path) ; 파일 이름 알아내기
    Tpath:=target . "\" . File_Path2
    FileCreateDir , %Tpath%     
    FileMove, %A_LoopField%, %Tpath%  
}
return
 
Item4: ;소스로 폴더 만들고 파일 이동
 
Loop, Parse, FullPathName, `n, `r
{
    Folder:=RegExMatch(A_LoopField,"^(.+\\)$",File_Path) ; 파일 or 폴더 유무 판별 
 
    if Folder=1
    continue
    
    RegExMatch(A_LoopField,"^(.+\\)(.+)\.",File_Path) ; 파일 이름 알아내기
    Tpath:=File_Path1 . "\" . File_Path2    
    FileCreateDir , %Tpath%     
    FileMove, %A_LoopField%, %Tpath%  ; 
}  
 
return
 
^!c:: ;타켓으로 폴더구조를 복사 
 
Item5: ;타켓으로 폴더구조를 복사 
IfWinActive, ahk_class TTOTAL_CMD
{
    
    ControlGetFocus, Control, ahk_class TTOTAL_CMD
    If (Control="TMyListBox1" or Control="TMyListBox2" or Control="LCLListBox1" or Control="LCLListBox2")
    {
        Temp:=Clipboard        
        SendMessage 1075, 2030, , , ahk_class TTOTAL_CMD  ; Copy Target path to clipboard
        Target:=clipboard
        SendMessage 1075, 2018, , , ahk_class TTOTAL_CMD ; Copy filenames to clipboard
        FullPathName:=clipboard
        Clipboard:=Temp
    }
 
    Loop, Parse, FullPathName, `n, `r
    {
        Folder:=RegExMatch(A_LoopField,"^(.+\\)$",File_Path) ; 파일 or 폴더 여부 확인
    
        if Folder=1
        {
            RegExMatch(A_LoopField,"(?<=[a-zA-Z]:).+\\$",Folder_Path) ; 폴더경로 추출     
            Tpath:=Target . "\" . Folder_Path   
            FileCopyDir %A_LoopField%, %Tpath% ,1
        }
    
        else
        {
            RegExMatch(A_LoopField,"(?<=[a-zA-Z]:).+\\(?=.+)",File_Path) ; 파일경로 추출 
            Tpath:=Target . "\" . File_Path 
            FileCreateDir , %Tpath%     
            FileCopy, %A_LoopField%, %Tpath% 
        }
    }
}
 
Return

 

수정 버전 첨부합니다 

 

image.png

 

 

 

Tc에서 파일 선택후 Ctrl+K 누르면 다음과 같은 메뉴가 뜹니다 

Copy to target create foler 는 TC 반대 패널에 파일이름으로 폴더를 만들고 파일 복사를 합니다 

Move to target create folder는 TC 반대 패널에 파일이름으로 폴더를 만들고 파일 이동을 합니다  

파일만 복사합니다 폴더는 복사하지 않습니다 

 

Copy to target with folder structure 는 파일 구조를 복사를 하며 단축키는 Ctrl+Alt+S 입니다 

파일과 폴더 둘다 복사합니다 

https://windowsforum.kr/lecture/15725623 홈으로 위로 목록
홈으로 위로 목록
번호 제목 글쓴이 조회 추천 등록일
[공지] 강좌 작성간 참고해주세요 gooddew - - -
3863 윈 도 우| bios 부팅과 uefi 부팅 기본개념 [4] 영구당 3411 6 03-25
3862 윈 도 우| 할당되지 않은 공간...1MB? [4] 밤이슬216 2279 5 03-24
» 소프트웨어| Total commander 에서 검색된 파일들을 폴더 구조와 함께 ... [8] 줄리아니 1208 6 03-22
3860 소프트웨어| 디펜터에서 화일 바이러스 잡을경우 해결방법 [1] 조랑말 2199 6 03-20
3859 소프트웨어| 4K UHD HDR 비지원 동영상 플레시 화면이 물빠짐현상 해결방법 [2] 조랑말 1536 1 03-20
3858 모 바 일| [Tip] 카카오톡 흔들어 QR 코드 생성하기 [3] asklee 2810 10 03-15
3857 소프트웨어| WinNTSetup.exe에 소소한 팁들 [18] suk 3550 25 03-09
3856 윈 도 우| 절전모드 바로가기 3형제 [6] suk 2250 8 03-09
3855 윈 도 우| 윈도우 10 설정편 Tips (보완) [12] 뉴썬 6104 18 03-08
3854 윈 도 우| 절전모드가 자동 해제되는 경우 극약 처방 [16] suk 2087 5 03-03
3853 기 타| 구글 드라이브 대역폭 제한으로 사본 만들기가 안될때 [8] Nick 2525 6 03-01
3852 소프트웨어| Firefox 86.0의 새로운 기능과 변경된 내용 [6] VₑₙᵤₛG 1722 4 02-24
3851 소프트웨어| 두고 두고 쓰는 필수 크롬 확장앱 [5] 노래빠바바 6051 2 02-21
3850 소프트웨어| 크로미움 브라우저에 검색엔진이 없을 때 Antory 1347 3 02-15
3849 윈 도 우| 바이오스 유저 프로필 삭제하기 5254 2185 2 02-13
3848 윈 도 우| 스크린샷 이쁘게좀 찍어 올립시다.. [ Tip ] [16] 메인보드 4024 18 02-10
3847 윈 도 우| 윈도우 설치하지 않고, 레지스트리로 윈도우 정보 확인 [4] suk 3743 8 02-08
3846 모 바 일| [팁] 아이폰 Tmap 자동실행 [1] asklee 2125 2 02-08
3845 하드웨어| 구형 메인보드에서 nvme SSD 사용하기 - BIOS [24] 디폴트 6254 12 02-05
3844 윈 도 우| 윈도우 시스템 복원 지점을 활성화 안 하는 방법 - 시스템 ... [18] 오스 3209 8 01-30
홈으로 위로 목록
XE1.11.6 Layout1.4.8