윈도우 / MS 이제 Windows 8.1에서 전체 화면의 '지원 종료' 경고가 표시됩니다

7 이랑 경고 메세지 없는 방법은 동일한듯합니다

참고로 7을 3년이 아닌 6년 연장 지원한다는 소문이 있는데, 이러면 8.1이랑 같이 종료되겠네요

어제 갱신하면서 재설치해 보았는데 지원 종료 메시지가 나오더군요.

하나둘 추억 저 넘어로 사라져 가네요. ^^;;

@ECHO OFF
>NUL 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
IF '%errorlevel%' NEQ '0' (
GOTO UACPrompt
) ELSE ( GOTO gotAdmin )
:UACPrompt
ECHO Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
ECHO UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"
"%temp%\getadmin.vbs"
EXIT /B
:gotAdmin
IF EXIST "%temp%\getadmin.vbs" ( DEL "%temp%\getadmin.vbs" )
TITLE EOSNotify-Clean up  nat.ee
CLS
ECHO URL：nat.ee
ECHO yyingc-create
ECHO QQ：1800619
TIMEOUT 3 >NUL
SET winsxs=%SystemRoot%\winsxs
ECHO.
ECHO Clean up EOSNotify WinSXS...
FOR /f %%i IN ('dir /b %winsxs%\^|findstr ".*microsoft-windows-eosnotify.*"') DO (
takeown /a /r /d Y /f "%winsxs%\%%i" >NUL
icacls "%winsxs%\%%i" /T /C /grant administrators:D >NUL
ECHO deleting WinSXS
ECHO %%i
RMDIR /s /q "%winsxs%\%%i"
)
ECHO.
ECHO Clean up EOSNotify manifest...
FOR /f %%i IN ('dir /b %winsxs%\Manifests^|findstr ".*microsoft-windows-eosnotify.*\.manifest"') DO (
takeown /a /f "%winsxs%\Manifests\%%i" >NUL
icacls "%winsxs%\Manifests\%%i" /grant administrators:D >NUL
DEL /F /S /Q "%winsxs%\Manifests\%%i"
)
TIMEOUT 3 >NUL
ECHO.
ECHO delete EOSNotify Registry...
FOR /f %%i IN ('REG QUERY HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\SideBySide\Winners^|findstr ".*microsoft-windows-eosnotify.*"') DO (
ECHO deleting Registry
reg delete %%i /f
)
TIMEOUT 3 >NUL
ECHO.
ECHO delete EOSNotify Tasks...
schtasks /delete /tn "\Microsoft\Windows\Setup\EOSNotify" /f
schtasks /delete /tn "\Microsoft\Windows\Setup\EOSNotify2" /f
TIMEOUT 3 >NUL
IF EXIST "%SystemRoot%\System32\EOSNotify.exe" (
ECHO.
ECHO delete EOSNotify.exe file...
taskkill /F /IM "%SystemRoot%\System32\EOSNotify.exe" 1>NUL 2>NUL
takeown /a /f "%SystemRoot%\System32\EOSNotify.exe" >NUL
icacls "%SystemRoot%\System32\EOSNotify.exe" /grant administrators:D >NUL
DEL /F /S /Q "%SystemRoot%\System32\EOSNotify.exe"
)
IF EXIST "%SystemRoot%\Migration\WTR\EOSNotifyMig.inf" (
ECHO.
ECHO delete EOSNotifyMig.inf file...
DEL /F /S /Q "%SystemRoot%\Migration\WTR\EOSNotifyMig.inf"
)
TIMEOUT 3 >NUL
ECHO.
ECHO optimization EOSNotify Registry settings...
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\SipNotify" /v "DontRemindMe" /t REG_DWORD /d "1" /f
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\SipNotify" /f /v "DateModified" /t REG_QWORD /d 0x0
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\SipNotify" /f /v "LastShown" /t REG_QWORD /d 0x0
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\EOSNotify" /v "DiscontinueEOS" /t REG_DWORD /d "1" /f
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\EOSNotify" /v "Discontinue" /t REG_DWORD /d "1" /f
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\EOSNotify" /f /v "DontRemindMe" /t REG_DWORD /d 1
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\EOSNotify" /f /v "LastRunTimestamp" /t REG_QWORD /d 0x0
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\EOSNotify" /f /v "TimestampOverride" /t REG_QWORD /d 0x0

reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\EOSNotify" /f /v "DiscontinueEOS" /t REG_DWORD /d 1
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\EOSNotify" /f /v "DontRemindMe" /t REG_DWORD /d 1
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\EOSNotify" /f /v "LastRunTimestamp" /t REG_QWORD /d 0x0
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\EOSNotify" /f /v "TimestampOverride" /t REG_QWORD /d 0x0
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\EOSNotify" /f /v "Discontinue" /t REG_QWORD /d 0x0
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\SipNotify" /f /v "DontRemindMe" /t REG_DWORD /d 1
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\SipNotify" /f /v "DateModified" /t REG_QWORD /d 0x0
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\SipNotify" /f /v "LastShown" /t REG_QWORD /d 0x0

reg add "HKLM\Software\Policies\Microsoft\Windows\Gwx" /v "DisableGwx" /t REG_DWORD /d "1" /f
reg add "HKLM\Software\Policies\Microsoft\Windows\WindowsUpdate" /v "DisableOSUpgrade" /t REG_DWORD /d "1" /f
reg add "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Image File Execution Options\EOSNOTIFY.EXE" /v "Debugger" /t REG_SZ /d "*" /f
reg add "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Image File Execution Options\SIPNOTIFY.EXE" /v "Debugger" /t REG_SZ /d "*" /f

TIMEOUT 3 >NUL
ECHO.
ECHO Press any key to exit……
PAUSE >NUL
EXIT
 

최신 정보를 다 반영한겁니다

CMD로 저장후 실행해주세요

7기준이지만, 딱히 문젠 없을껍니다