기 타 cmd스크립트 짜는데 왜이리 안되는지 도음좀 부탁드립니다 ㅠㅠ
2024.03.20 23:11
rem @echo off
set line=first
for /f "usebackq skip=1" %%i in (`wmic useraccount where name^='%%USERNAME%%' get sid`) do (
if %line% EQU first (set SID=%%i)
set line=no
)
@echo SID : %SID%
위처럼 윈도우 로그온된 SID를 따와서 변수 안에 집어넣을려고 하는데 뭔삽질을 해도 안되네요
wmic useraccount where name^='%%USERNAME%%' get sid 의 결과물은
3줄인데 첫번째줄은 제목행이고 두번째줄이 SID이고 3번째줄은 빈줄 입니다.
skip을 써서 첫번재줄 날리고 if문 으로 3번째 빈줄 날리기 위해 저렇게 짰는데
어떤 삽질을 다해봐도 최종결과물은 비어 있습니다.
댓글 [4]
-
라랑 2024.03.20 23:32
-
무월 2024.03.20 23:33
ChatGPT에게 올바르게 작동 되도록 수정을 요청했습니다. ㅡㅅㅡ;;;
@echo off
setlocal enabledelayedexpansion
set line=first
for /f "usebackq skip=1" %%i in (`wmic useraccount where name^='%USERNAME%' get sid`) do (
if "!line!"=="first" (
set SID=%%i
set "line=no"
)
)
echo SID : %SID%
pause
-
입니다 2024.03.21 06:01
@echo off
echo.
:G1
echo "1번"
FOR /f "tokens=1,2 delims==" %%A in ('wmic useraccount where name^="%USERNAME%" get sid /value') do (
If /i "%%A" equ "SID" Set "SID1=%%B" & GOTO :G2
Echo %%A)
:G2
echo.
echo "2번"
FOR /f %%A in ('wmic useraccount where name^="%USERNAME%" get sid ^| Find "-"') do (
Set "SID2=%%A" & GOTO :G3
Echo %%A)
:G3
echo.
echo "3번"
set /a Count=0
FOR /f %%A in ('wmic useraccount where name^="%USERNAME%" get sid') do CAll :GetLine %%A
GOTO :R123
:GetLine
set /a Count+=1
If "%Count%" equ "2" Set "SID3=%1" & GOTO :R123
echo %Count% %1
Exit /B
:R123
echo.
echo "결과"
echo "1번" %SID1%
echo "2번" %SID2%
echo "3번" %SID3%
:G4
echo.
echo "4번"
set /a Count=0
setlocal enabledelayedexpansion
FOR /f %%A in ('wmic useraccount where name^="%USERNAME%" get sid') do (
set /a Count+=1
If "!Count!" equ "2" Set "SID4=%%A" & echo "4번1" !SID4!
If defined SID4 GOTO :R4
echo !Count! %%A)
:R4
echo "4번2" %SID4%
endlocal
echo "4번3" %SID4%
:FInish
pause
-
일상다반사 2024.03.25 12:36
도움 주신 모든 분들께 감사드립니다.
덕분에 잘해결 되었습니다.
배치파일 스크립트가 생각보다 복잡하네요 ㅠㅠ
번호 | 제목 | 글쓴이 | 조회 | 등록일 |
---|---|---|---|---|
[공지] | 질문과 답변 게시판 이용간 유의사항 | gooddew | - | - |
99704 | 윈 도 우| 사용자 휴대폰 통화 기능 사용 문의 | 발랄귤 | 137 | 04-16 |
99703 | 하드웨어| 주의뜬 하드 자료를 복사할때요. [4] | 감사합니다 | 297 | 04-16 |
99702 | 소프트웨어| Emeditor 바꾸기(위, 아래쪽) 질문입니다. | 파풍초 | 80 | 04-16 |
99701 | 소프트웨어| 서로 다른 윈도우10의 엣지브라우저 즐겨찾기 제거 [3] | ccnet | 206 | 04-16 |
99700 | 윈 도 우| PE의 Program Files내의 프로그램 교체방법 [2] | 익명7861 | 358 | 04-16 |
99699 | 윈 도 우| 윈도우11 계정 사진 오류 입니다. [2] | 마린블루 | 302 | 04-15 |
99698 | 윈 도 우| 엣지의 브라우저를 닫을 때마다 지울 항목 선택을 레지스트... [10] | 투윤 | 169 | 04-15 |
99697 | 서버 / IT| 구글 플레이 스토어에서 특정 앱을 apk 로 저장할 수 있나요? [4] | brucex | 247 | 04-15 |
99696 | 윈 도 우| 공유기 인터넷 끊김 질문 [2] | 솔모로 | 642 | 04-15 |
99695 | 윈 도 우| Ventoy로 파티션을 나누었는데 디스크 할당이 안되요. [3] | 익명7861 | 582 | 04-14 |
99694 | 기 타| 혹시 이미지 수정좀 할수있을까요 [4] | QOR | 615 | 04-14 |
99693 | 하드웨어| 삼성 아티북인데 너무 느리네요 [14] | 『ⓖⓤⓝ』 | 677 | 04-14 |
99692 | 하드웨어| 컴퓨터 전원 문제 [6] | 아프리카태 | 594 | 04-14 |
99691 | 소프트웨어| 윈도우 업데이트 되면서 디펜더에서 감지.. [1] | 이슬 | 368 | 04-14 |
99690 | 소프트웨어| 더 큰 디스크에 복원시 용량을 확장해주는 백업프로그램 있... [2] | 좋게멋지게 | 283 | 04-14 |
99689 | 소프트웨어| Acronis True Image 는 업데이트를 안하네요? [1] | 좋게멋지게 | 516 | 04-14 |
99688 | 윈 도 우| 윈 xp 블랙 에디션 [1] | 개골구리 | 540 | 04-14 |
99687 | 소프트웨어| 파티션 문의 [2] | 에로스타 | 232 | 04-14 |
99686 | 하드웨어| HDMI에서 DP로 케이블 교체했는 데 화면이 끊김이 [3] | toto65 | 812 | 04-13 |
99685 | 기 타| mega 다운시 전송 할당량 초과? [5] | 짚신 | 411 | 04-13 |
@echo off
for /f "tokens=2 delims== " %%a in ('wmic useraccount where "name='%username%'" get sid /value') do (
echo SID: %%a
)
pause
--------------- 아 꺼내서 쓰셔야 되니까 이게 아니겠군여 죄송합니다.
이럴땐 어쩔수 없이 goto 쓰기 싫지만 언능 튀어야 되더라구요; 배치에서 for문의 특징인듯
@echo off
setlocal enabledelayedexpansion
for /f "tokens=2 delims== " %%a in ('wmic useraccount where "name='%username%'" get sid /value') do (
set "SID=%%a"
goto :TTT
)
:TTT
echo SID: %SID%
pause