윈 도 우 할당되지 않은 디스크 번호 가져오기 배치파일 질문드립니다.

여분의 하드의 모든 볼륨 삭제후 테스트했습니다.ㅡ,.ㅡ 다양한 환경에서 확인되지는 않았지만... 오류 있으면 댓글로...

아마 볼륨이 없는 디스크가 여러개면 마지막 디스크 번호를 가져올 것 같습니다. 한글 포함으로 인코딩 ANSI로 저장...

get_disk_wo_vol.cmd

@echo off

for /f "tokens=1,2" %%a in ('echo lis dis ^| diskpart') do if not "%%b"=="" set i=%%b

for /l %%a in (0,1,%i%) do (for /f "tokens=*" %%b in ('^(echo sel dis %%a^&echo det dis^)^|diskpart') do if "%%b"=="볼륨이 없습니다." set noVolDisk=%%a)

echo %noVolDisk%

pause

지후빠님 앞전에 이어서 아래 상황 도움 부탁드립니다.

위 스크립트에서 디스크 번호 변수를 잘 받아옵니다.  오늘 안되는 상황이 와서 왜 안되나 살펴보니

아래처럼 비어있는 이동식 디스크가 있을경우 해당 드라이브가 변수로 받아와 집니다. ㅜ

det disk 명령을 보니 역시 이동식 디스크에도 "볼륨이 없습니다." 라는 문구가 있어서 

위에서 말씀하신 "볼륨이 없는 디스크가 여러개면 마지막 디스크 번호를 가져올 것 같습니다" 

상황인거 같습니다.

이동식을 살펴보니 상태: 미디어 없음 이라는 문구가 있어서....

볼륨이 없습니다.  이면서  상태 : 미디어 없음 이 아니면 %noVolDisk%에 값으로  디스크 번호를 받으려면

어떻게 해야할까요??

유형이 USB는 제외시킵니다. first_match 값이 1이면 첫번째 검출된 디스크번호를 가져오고,

0으로하면 마지막 검출된 디스크 번호를 가져옵니다. get_disk_wo_vol_3.cmd

@echo off

set first_match=1

for /f "tokens=1,2" %%a in ('echo lis dis ^| diskpart') do if not "%%b"=="" set i=%%b

for /l %%a in (0,1,%i%) do (set VolType=

for /f "tokens=1,2 delims=:" %%b in ('^(echo sel dis %%a^&echo det dis^)^|diskpart') do (

if "%%c"==" USB" set VolType=USB

if "%%b"=="볼륨이 없습니다." if not defined VolType (set noVolDisk=%%a&&if %first_match%==1 goto :NEXT)))

:NEXT

echo %noVolDisk%

pause

상태가 "미디어 없음"일때를 배제하고 싶으시면 아래처럼 하실 수 있습니다. get_disk_wo_vol_4.cmd

@echo off

set first_match=1

for /f "tokens=1,2" %%a in ('echo lis dis ^| diskpart') do if not "%%b"=="" set i=%%b

for /l %%a in (0,1,%i%) do (set VolType=

for /f "tokens=1,2 delims=:" %%b in ('^(echo sel dis %%a^&echo det dis^)^|diskpart') do (

if "%%c"==" 미디어 없음" set VolType=USB

if "%%b"=="볼륨이 없습니다." if not defined VolType (set noVolDisk=%%a&&if %first_match%==1 goto :NEXT)))

:NEXT

echo %noVolDisk%

pause