기 타 배치 파일 질문 드립니다.

선택한 번호에 해당하는 파일만 실행하려고 할 때,

해당 파일명을 반환하는 변수명을 어떻게 작성하는 것인지 잘 모르겠습니다. 

올려주신 내용 참고하여 저도 더 검색해보도록 하겠습니다. 

글 올려주셔서 감사합니다. 

 

올려주신 글 보고, 지금 테스트 해보니 잘 됩니다. 

가르쳐 주셔서 많은 도움이 되었습니다. 

감사합니다. 

추가로 한 가지 여쭤봅니다.

위에서 파일명에 느낌표가 들어가 있는 파일인 경우, 목록 출력이나 실행에 문제가 있어서

혹시 느낌표가 들어가 있는 파일도 정상적으로 출력 및 실행하려면

어느 부분 수정이 필요한지 궁금합니다. 

 

 

https://windowsforum.kr/lecture/20421860
그것에 관해 제가 쓴 글이 위에 있는데...

제가 쓰고도 헷갈리고 하다보면 또 알던것과 다르게 동작하는 경우가 많습니다.

(특히 느낌표가 처리하려면 제일 고약합니다)

 

그래서 제가 원래 다른 언어로 알려드릴랬는데, 뭐 별일 있겠나 싶어서 그냥 배치파일로 만들어 드린건데 기어코 문제를 일으키는군요.

배치파일로만 해결하는건 그냥 관리자권한 위한 경로를 처리하며 실행할때나 할만하지,

실제로 사용해야하는

중간의 주요 처리를 다 감안하면서 100% 배치파일로 하는건 정말 할짓 못됩니다.

 

그러므로 cmd + vbs 형태로 알려드리겠습니다.

 

메인 cmd 파일

------------------------------------------------------------------------------------------------

@echo off

setlocal enabledelayedexpansion

 

echo.

echo.

 

cscript "txt만 읽어서 노트패드로 실행하는 예제2_sub.vbs"

 

echo.

echo.

 

pause

------------------------------------------------------------------------------------------------

 

서브 vbs 파일

------------------------------------------------------------------------------------------------

 

Set objShell = CreateObject("WScript.Shell")

 

' 경로 설정

' folderPath = "C:\내 파일\"

' 예제용 경로이므로 필요에 따라 적절히 변경하면 됨.

folderPath = objShell.CurrentDirectory & "\"

 

 

' 파일 목록 가져오기

Set objFSO = CreateObject("Scripting.FileSystemObject")

Set folder = objFSO.GetFolder(folderPath)

Set files = folder.Files

 

' 확장자가 txt인 파일들의 이름만(확장자 없이 파일명만) 불러오기

Set txtFiles = CreateObject("Scripting.Dictionary")

count = 1

 

For Each file In files

    If objFSO.GetExtensionName(file.Name) = "txt" Then

        fileName = objFSO.GetBaseName(file)

        txtFiles.Add count, fileName

        count = count + 1

    End If

Next

 

' 파일 목록 출력

WScript.Echo "파일 목록:"

WScript.Echo "------------"

 

For i = 1 To txtFiles.Count

    WScript.Echo i & ". " & txtFiles(i)

Next

 

WScript.Echo "------------"

 

' 사용자에게 번호 입력 받기

choice = InputBox("번호를 선택하세요 (1-" & txtFiles.Count & "):")

choice = CInt(choice)

 

' 선택한 파일 실행

If choice >= 1 And choice <= txtFiles.Count Then

    selectedFile = txtFiles(choice)

    WScript.Echo selectedFile & " 를 선택하였습니다."

 

    ' 파일 실행

    objShell.Run "notepad """ & folderPath & selectedFile & ".txt""", 1, False

Else

    WScript.Echo "올바른 번호를 선택하세요."

End If

 

------------------------------------------------------------------------------------------------

 

 

 

txt만 읽어서 노트패드로 실행하는 예제2.cmd

txt만 읽어서 노트패드로 실행하는 예제2_sub.vbs

 

 

여전히 챗GPT가 유용하군요.

vbs로 새로 만들어 달라니까 바로 쏙 뽑아주는군요.

 

참고로 wscript.exe cscript.exe가 무슨 차이인지 보통 잘 모르는데,

wscript는 윈도우 기준으로, cscript는 텍스트 기준으로 vbscript(.vbs) jscript(.js)를 실행해주는 명령입니다.

 

다른건 저도 잘 모르겠고,

vbs js 코드 내부에서 wscript.echo라고 했을때

wscript로 실행하면 메시지박스로 뜨고, cscript로 실행하면 cmd창에 바로 echo로 뜹니다.

다만 inputbox는 그러지 못하는거 아닌가 싶긴 합니다만...

 

참고로 파워셸로 하면 아예 닷넷윈폼을 불러와서 목록을 띄워서 할수도 있습니다만,

그거까지 가면 더 복잡해질거 같아 위 내용을 추천드립니다.

하고 싶으시면 챗GPT로 만들어달라고 해보세요.

 

다만 챗GPT가 바로 완벽한 코드를 내주는게 아니기 때문에

원하는 결과와 다르면 수정할 능력이 없으면 하기 힘듭니다.

 

 

잘보니 또 딕셔너리를 만들어줬군요.

이게 무슨 개념인지 잘 이해 안갈수도 있는데

키값과 밸류값을 가지는 자료형 개념입니다.

 

어렵게 생각할건 아니고

단지 배열의 일종이라 생각하면 되는데

배열은 0,1,2,3,4 .. 이런 숫자로만 배열에서 값을 불러오는데 쓰는데

키-밸류 방식은 키가 숫자도 되고 문자도 되는 방식이라는 차이정도가 있습니다.

(사실 본문은 배열로 해도 되는데 딕셔너리가 확장성 좋으니 갖다 쓴 모양이군요)

 

이게 딕셔너리 객체 선언이고

Set txtFiles = CreateObject("Scripting.Dictionary")

 

이렇게 하면 키,밸류가 입력되는 거고

txtFiles.Add count, fileName

 

호출할때는

selectedFile = txtFiles(choice)

이런식으로 가져오는거죠.

 

여기서 count와 choice 부분은 다른 용도로 쓰게되면 문자로도 처리가 가능해서 유용한 자료형입니다.

근데 여기선 굳이 필요없는데 어렵게 만들어놨군요.

동적배열을 만들어서 가변배열을 쓰기 번거로워서 그랬나보긴 합니다만...

 

올려주신 글을 읽어보니 매우 복잡한 문제였네요....

바쁘신데 시간내어 주셔서 죄송하고 감사합니다.

예제 파일 보고 잘 배워보도록 하겠습니다. 

수고 많으셨습니다. 거듭 감사 드립니다. 

 

추가로 올려주신 예제를 보고 조금씩 배워보도록 하겠습니다.

거듭 감사드립니다.