기 타 바로가기 바이러스 제거 배치파일 소스입니다. 2가지 문제점..
2016.10.09 10:26
배치파일에서 해당 파일이 있으면 실행하고 안하고 결정하듯이 ( if exist ~ )
프로세서가 현재 메모리에 상주하고 있는지 알 수 있는 명령어(방법)이 뭐가 있을까요?
무슨 문제인가하면??
taskkill /f /im wscript.exe /t
위와 같은 명령 사용시 해당 프로세서가 없으면 오류 메시지가 나오는데...
오류 메시지를 안보이게 하기위해
taskkill /f /im wscript.exe /t >nul
>nul 명령은 안먹히더라구요.
해서 해당 프로세서가 있으면 실행하고 없으면 건너 뛸려고 합니다.
참고로 지난번 USB 바로가기 바이러스 관련하여 suk님의 도움으로 현재 잘 되고 있습니다.
소스파일:
@echo off
taskkill /f /im wscript.exe /T
attrib -r -s -h "%TEMP%\*.jse" >nul
attrib -r -s -h "%TEMP%\R.jpg" >nul
if exist "%TEMP%\*.jse" del /f/a/q "%TEMP%\*.jse" >nul
if exist "%TEMP%\R.jpg" del /f/a/q "%TEMP%\R.jpg" >nul
attrib -r -s -h "%APPDATA%\Microsoft\*.jse" >nul
if exist "%APPDATA%\Microsoft\*.jse" del /f/a/q "%APPDATA%\Microsoft\*.jse" >nul
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (for /f "tokens=1 usebackq" %%b in (`"fsutil fsinfo drivetype %%a: | findstr /i "Removable 이동식""`) do (
attrib -r -h -s /s /d %%b\*.*
if exist "%%b\*.lnk" del /f/a/q "%%b\*.lnk"
if exist "%%b\*.jse" del /f/a/q "%%b\*.jse"
)
)
위 배치 파일에서 문제점은 2개 입니다.
하나는 맨위의 설명대로 해당 프로세서가 없을시 나오는 오류 메시지...
또하나는 attrib -r -h -s /s /d 명령인데
폴더안에 서브 폴더가 있을시 너무 많으면 처리 시간이 오래 걸린다는 겁니다.
루트에 있는 폴더만 속성 해제하는 방법이 없나요?
댓글 [4]
-
suk 2016.10.09 11:44
-
하이하루 2016.10.09 14:19
우왕..감사합니다. ^^
suk님의 도움으로 참으로 유용하게 쓰이고 있습니다.
오늘은 제가 세무회계 시험감독으로 있는데....USB에 바로가기 바이러스 걸려 여러 감독관님들 정답 복사하는데 문제가 많이 생겼습니다.
바로 해결되었네요.
요거 넣고 실행한번씩한 해주면 다 해결되니...ㅎㅎ
386세대라 옛날 도스만 알고 더구나 오랜만에 만지다 보니 지식이 부족하였는데..
suk님 보면 무림세계의 고수 같습니다. 십존의 1일인이랄까 ㅎㅎㅎ
여러모로 감사한 마음입니다.
환절기 건강 조심하시고 즐겨하시는 일들이 더욱 좋아지시길 기원합니다.
-
Playing 2016.10.09 12:21
두분 말씀 보고 조용히 물러납니다 ~~ ~~ ^^
하이하루님이 원하시는 바를 얻으시길!
-
하이하루 2016.10.09 14:20
Playing님 감사합니다. suk님 도움으로 모두 해결될듯합니다.
좋은 주말 보내시길...건강하세요.
번호 | 제목 | 글쓴이 | 조회 | 등록일 |
---|---|---|---|---|
[공지] | 질문과 답변 게시판 이용간 유의사항 | gooddew | - | - |
66092 | 윈 도 우| 이번 윈10th2 rs1 각각 설치하고나면 .. [1] | 바드퀸 | 882 | 10-16 |
66091 | 기 타| sk 브로드밴드 이거 뭔지.. [3] | 뷰리풀투데 | 1234 | 10-16 |
66090 | 하드웨어| 이미지 깨짐 현상... [1] | 윈도포도 | 651 | 10-15 |
66089 | 소프트웨어| PDF 파일에 폰트 내장하기 [2] | 유기농 | 960 | 10-15 |
66088 | 윈 도 우| 저좀 도와주세요 ㅠㅠㅠ [10] | 바이티 | 903 | 10-15 |
66087 | 윈 도 우| IE11에서 세션 공유 및 유지 방법 [2] | 메리아 | 1087 | 10-15 |
66086 | 소프트웨어| VideoReDo TVSuite H.264 5.1.1.719b 사용하시는 분께 질문... | 잇힝이 | 821 | 10-15 |
66085 | 기 타| 혹시 이 폰트이름 아시는분? [3] | alljoy | 843 | 10-15 |
66084 | 윈 도 우| 도와주세요. 즐겨찾기가 모두 삭제되었습니다. [5] | 부가티 | 1142 | 10-15 |
66083 | 윈 도 우| 이 네트워크에 연결할 수 없습니다. | 가드리아 | 9477 | 10-15 |
66082 | 윈 도 우| 윈10에서 윈7 32비트에서 돌아가는 프로그램을 사용할수 있... [2] | 클리엔테스 | 1146 | 10-15 |
66081 | 윈 도 우| Windows Server 2016 이 MSDN 를 설치한후... | gtxkim | 887 | 10-15 |
66080 | 소프트웨어| USB 복제 프로그램이 있나요? [2] | 부가티 | 1511 | 10-15 |
66079 | 윈 도 우| 윈도우 10 클린설치후 안정화? [1] | 쭌쭌 | 1120 | 10-15 |
66078 | 소프트웨어| 스크린샷에 보이는 폰트가 무엇인지 문의 [1] | nhk | 542 | 10-15 |
66077 | 소프트웨어| Total commander 문의드립니다. [3] | 하하돌다리 | 612 | 10-15 |
66076 | 윈 도 우| 윈도우 10 레드스톤1 오디오 싱크 문제 [1] | 천사와의데 | 698 | 10-15 |
66075 | 소프트웨어| 토탈커맨더에선 왜 이게 안될까요? [8] | 윈도면도 | 1006 | 10-14 |
66074 | 기 타| 복사-자동복사 [7] | 虎視 | 1137 | 10-14 |
66073 | 윈 도 우| windows 10 [1] | zzazzer | 1269 | 10-14 |
tasklist | find /i "wscript.exe" && (taskkill /f /im wscript.exe /T)
tasklist | find /i "cscript.exe" && (taskkill /f /im cscript.exe /T)
for /f "tokens=* usebackq" %%a in (`"dir /a:-d/b/s "%TEMP%\*.jse" "%TEMP%\R.jpg""`) do del /f/a/q "%%~a"
for /f "tokens=* usebackq" %%a in (`"dir /a:-d/b/s "%APPDATA%\Microsoft\*.jse""`) do del /f/a/q "%%~a"
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (for /F "tokens=1 usebackq" %%b in (`"fsutil fsinfo drivetype %%a: | findstr /i "Removable 이동식""`) do (
for /F "tokens=* usebackq" %%c in (`"dir /a/b %%b\"`) do attrib -r -h -s "%%b\%%c"
for /F "tokens=* usebackq" %%c in (`"dir /a:-d/b "%%b\*.lnk" "%%b\*.jse""`) do del /f/a/q "%%b\%%c"
) )
좀더 간단하고 더 강력하게 만들어봤습니다.
프로세스가 있는 경우에만 작동하도록 했습니다 cscript.exe도 wscript.exe와 비슷해서 추가했는데 필요없으시면 생략하시면 됩니다.
파일을 찾는 경우, if 로 찾으면 파일 특성에 따라서 잡히지 않는 파일도 있더군요
dir 옵션에 따라서는 전부 다 검색이 됩니다. 어차피 삭제가 목적이시면 굳이 attrib로 속성을 변경하진 않으셔도 삭제됩니다
마지막으로 이동식 usb에 attrib 속성 변경하는건 폴더만 할 수도 있는데요. 제가 볼 때 루트에 있는 파일들도 attrib 적용해야 할 듯 해서..
저렇게 했습니다. 폴더만 하시려면 dir /a/b 부분을 dir /a:d/b 이렇게 수정하시면 됩니다.
* 루트에 있는 폴더만 적용되는 방법입니다.
바로가기라는 바이러스도 있었군요. . 별의 별 바이러스가 다 있군요.
R.jpg도 그렇고 미스테리한 요소가 있네요.
bat 파일 첨부했습니다
* 오류메시지는 신경 안 쓰셔도 됩니다만 1>nul 2>nul 이렇게 하시면 오류 메시지가 보이지 않을 겁니다.