소프트웨어 ahk 스크립트 수정 좀 부탁드려도 될까요

#NoEnv 
SetBatchLines -1 
Process Priority,,R 
ChangeDisplayOrientation(1)
BlockInput Mouse        ; user mouse input is ignored during MouseMove 
CoordMode Mouse, Screen ; absolute coordinates 
SetMouseDelay -1        ; fastest action 

MouseGetPos x0, y0      ; get initial mouse pointer location 
SetTimer WatchMouse, 1  ; run the subroutine fast (10..16ms) 
Return 

WatchMouse: 
 MouseGetPos x, y     ; get current mouse position 
 xn:=x0+y0-y
 yn:=y0-x0+x
 x0:=(xn>A_ScreenWidth) ? A_ScreenWidth : (xn<0) ? 0 : xn
 y0:=(yn>A_ScreenHeight) ? A_ScreenHeight : (yn<0) ? 0 : yn
 MouseMove x0, y0, 0  ; set new position as old, for the next timer 
Return 

z::
ResetDisplay(0)
ExitApp

return

; Orientation
;    0  - DMDO_DEFAULT
;    1  - DMDO_90
;    2  - DMDO_180
;    3  - DMDO_270

; Display:
;   The name of the display device. Usually something like: \\.\DISPLAY1
;   If omitted, uses the default display device.

; dwflags:
;   0   - change dynamically (use ResetDisplay() to reset to settings in registry)
;   1   - change dynamically and update registry (CDS_UPDATEREGISTRY)
;   2   - test if the requested mode could be set (CDS_TEST)

ChangeDisplayOrientation(Orientation, Display="", dwflags=0)
{
    ; DEVMODE is 156 bytes on Windows XP and later.
    ; It is smaller on earlier versions of Windows, but that's okay.
    VarSetCapacity(devmode, 156, 0)
    NumPut(156, devmode, 36)    ; devmode.dmSize := sizeof(devmode)
    
    ; Get the current resolution and orientation.
    if ! DllCall("EnumDisplaySettingsA"
        , "uint", Display ? &Display : 0  ; device name or NULL
        , "int", -1  ; ENUM_CURRENT_SETTINGS
        , "uint", &devmode
        , "uint", 0)
        return ; FAILED
    
    ; Get current resolution.
    dmPelsWidth  := NumGet(devmode, 108)
    dmPelsHeight := NumGet(devmode, 112)

    if (mod(NumGet(devmode, 52),2) != mod(Orientation,2))
    {  ; Swap height and width.
        NumPut(dmPelsHeight, devmode, 108) ; width
        NumPut(dmPelsWidth,  devmode, 112) ; height
    }
    
    ; Set orientation.
    NumPut(Orientation, devmode, 52)
    
    ; Update display settings.
    return DllCall("ChangeDisplaySettingsExA"
        , "uint", Display ? &Display : 0
        , "uint", &devmode
        , "uint", 0
        , "uint", dwflags
        , "uint", 0)
    
    /* Return values for ChangeDisplaySettings 
    #define DISP_CHANGE_SUCCESSFUL       0
    #define DISP_CHANGE_RESTART          1
    #define DISP_CHANGE_FAILED          -1
    #define DISP_CHANGE_BADMODE         -2
    #define DISP_CHANGE_NOTUPDATED      -3
    #define DISP_CHANGE_BADFLAGS        -4
    #define DISP_CHANGE_BADPARAM        -5
    #define DISP_CHANGE_BADDUALVIEW     -6
    */
}

ResetDisplay(Display="")
{
    return DllCall("ChangeDisplaySettingsExA"
        , "uint", Display ? &Display : 0  ; device name or NULL
        , "uint", 0, "uint", 0, "uint", 0, "uint", 0)
}