윈 도 우 USB에서 win7 사용하기
2010.10.31 01:06
스누피님의 'USB에 win7 설치하기'나
우금티님의 snapshot.exe 혹은 Hyper-V에 설치한 이미지를 이용하는 방법이 있지만
약간 다르게 USB에서 win7 사용하는 방법에 관한 글이 있어서 소개합니다.
원문링크: https://www.boot-land.net/forums/index.php?s=bb22e75502f16ddc5909e181bf273a8a&showtopic=9196
위 글에는 USB 디스크를 직접 사용하는 방법과 VHD를 이용하는 방법 두 가지를 설명하는 데 원리는 같습니다.
이 글에서는 제가 테스트해 본 VHD를 이용한 방법에 관해서만 소개합니다.
1. 하드디스크에 VHD를 만들어 win7을 설치합니다.( 기존에 VHD를 만들어 사용하신다면 그대로 사용하셔도 됩니다.)
2. VHD에 설치한 win7에서 usbbootfix.bat 를 실행한 후
다른 운영체제나 PE로 부팅하여 VHD를 USB에 복사합니다.
3. USB의 파티션에 활성( Active)을 걸어 줍니다.
4. USB안의 VHD를 연결( attach)해서 다음 명령으로 USB에 부팅파일을 만들어 줍니다.
bcdboot.exe k:\windows /l ko-kr /s j:
-? k: 는 VHD 드라이브 문자이고 j: 는 USB의 드라이브 문자입니다.
끝입니다. USB로 부팅하여 테스트 합니다.
<usbbootfix.bat 의 내용>
----------------------------------------------------------------------------------------------------------------
@echo off
if "%1"=="fix" goto :fix
rem -- install task
copy /y "%~f0" "%SystemRoot%\system32\usbbootfix.bat"
SCHTASKS /Create /RU SYSTEM /SC ONEVENT /MO "*[System[Provider[@Name='Microsoft-Windows-UserPnp'] and EventID=20003]]" /EC System /TN USBBootFix /TR "'%SystemRoot%\system32\usbbootfix.bat' fix" /F
rem -- apply other settings
reg add HKLM\SYSTEM\CurrentControlSet\services\pciide /v Start /t REG_DWORD /d 0x0 /f
reg add HKLM\SYSTEM\CurrentControlSet\services\msahci /v Start /t REG_DWORD /d 0x0 /f
reg add HKLM\SYSTEM\CurrentControlSet\services\intelide /v Start /t REG_DWORD /d 0x0 /f
reg add HKLM\SYSTEM\CurrentControlSet\services\viaide /v Start /t REG_DWORD /d 0x0 /f
rem -- run :fix once after install
:fix
call :fixservice usbehci "Boot Bus Extender"
call :fixservice usbohci "Boot Bus Extender"
call :fixservice usbuhci "Boot Bus Extender"
call :fixservice usbhub "System Bus Extender"
call :fixservice usbstor "SCSI miniport"
goto :eof
:fixservice
setlocal
set Start=
set Group=
for /f "skip=2 tokens=1,2,*" %%I in ('reg query HKLM\SYSTEM\CurrentControlSet\services\%~1') do (
if "%%I"=="Start" set Start=%%K
if "%%I"=="Group" set Group=%%K
)
if not "%Start%"=="0x0" reg add HKLM\SYSTEM\CurrentControlSet\services\%~1 /v Start /t REG_DWORD /d 0x0 /f
if not "%Group%"=="%~2" reg add HKLM\SYSTEM\CurrentControlSet\services\%~1 /v Group /t REG_SZ /d "%~2" /f
endlocal
goto :eof
----------------------------------------------------------------------------------------------------------------
주요 내용은
레지스트리에 등록된 하드 디스크 컨트롤러에 관한 서비스 값 중에서 'Start' 값을 0 으로 변경하고
USB에 관련된 서비스 값 중에서 'Start'와 'Group' 값을 0과 'Boot....'으로 변경한 뒤
EventID=20003( 서비스 설치) 가 생기면 위 배치 파일중 USB에 관련된 명령을 실행하게끔
작업 스케줄러에 등록하는 내용입니다.
드라이버를 설치하게 되면
HKLM\SYSTEM\CurrentControlSet\services와 기타 경로에 드라이버 정보를 등록하게 되는데
윈도우가 부팅하면서 이 곳의 레지스트리를 읽어서 드라이버를 로드하는 것 같습니다.
'Start' 값데이타가 0 인 드라이버는 부팅에 필요한 드라이버라는 뜻입니다.
USB 디스크 드라이버의 'Start' 기본값은 3 입니다.
'Group' 값 또한 구체적으로 로딩순서를 정하는 값인데
HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\ServiceGroupOrder 에 로딩순서대로
나열한 'Group' 값이 있습니다.
5. USB에 설치된 win7을 다른 컴퓨터에서 사용하려면 사용할 컴퓨터의 하드 디스크 컨트롤러 드라이버의
'Start' 값을 0 으로 변경한 뒤에 사용합니다.
어떤 드라이버인지 확실히 모를 경우 StorageBootStart.bat 를 실행한 뒤 종료한 다음 사용합니다.
StorageBootStart.bat 는 win7 에 미리 설치된 모든 하드 디스크 컨트롤러 드라이버의 'Start' 값을 0으로 변경시킵니다.
번호 | 제목 | 글쓴이 | 조회 | 추천 | 등록일 |
---|---|---|---|---|---|
[공지] | 강좌 작성간 참고해주세요 | gooddew | - | - | - |
763 | 서버 / IT| 해킹과 보안 -2- | gooddew | 6052 | 0 | 12-19 |
762 | 서버 / IT| [팁:정보_수정] 미친 알약(ALyac) [12] | 우금티 | 14870 | 0 | 12-21 |
761 | 소프트웨어| [팁] : Firefox 4 와 IE tab 문제 해결 간단히 [16] | 우금티 | 8267 | 0 | 03-22 |
760 | 소프트웨어| 초보도 하는 유튜브 동영상 다운 받기 [8] | gooddew | 7970 | 0 | 12-19 |
759 | 소프트웨어| 광고 주소 찾는 초~~~~ 허접한 팁 [1] | ever | 5723 | 0 | 12-19 |
758 | 소프트웨어| 그리드 컴퓨팅 - 미확인 우주 생명체 프로젝트 [2] | Native 64 | 8102 | 0 | 12-19 |
757 | 윈 도 우| win7 설치 이미지 사용자 지정 [21] |
|
14014 | 0 | 12-16 |
756 | 윈 도 우| [팁] : 명령창 풀스크린 [7] | 우금티 | 7307 | 0 | 12-16 |
755 | 하드웨어| AMD 레이드 구성시 "NCQ" 과연 효과 있을까? [13] |
|
12043 | 0 | 12-13 |
754 | 소프트웨어| [초보용] MS OFFICE 2010 시디키 변경 방법 [1] | gooddew | 30549 | 0 | 12-15 |
753 | 소프트웨어| IRQ설정으로 시스템 속도향상의 진실 [32] |
|
11661 | 0 | 12-11 |
752 | 소프트웨어| W-fi 존에서 노트북 무선 인터넷 공짜로 사용하기 [7] |
|
14346 | 0 | 12-11 |
751 | 소프트웨어| 인터넷 연결을 하지 않고 Windows Live 필수 패키지 2011을... [2] |
|
9198 | 0 | 12-07 |
750 | 소프트웨어| 독일어판 파티션메니져11pro 설명입니다 [1] | 파란하눌 | 18363 | 0 | 12-04 |
749 | 소프트웨어| ISO제작명령을 Makeisofs.exe로 할때, | 파란하눌 | 7221 | 0 | 12-04 |
748 | 소프트웨어| Mbrfix로 초기화만 알아도.. [3] |
|
9200 | 0 | 02-21 |
747 | 윈 도 우| 윈도우7에서 부팅스크린 변경 [10] |
|
10868 | 0 | 11-30 |
746 | 윈 도 우| 하드디스크에 PE 설치하기 [2] | 조르빈 | 20341 | 0 | 03-20 |
745 | 윈 도 우| 디스플레이 드라이버가 응답을 중지하고 복구됨 [16] |
|
35513 | 0 | 11-26 |
744 | 윈 도 우| 윈도우7 인터넷 끊김현상 [24] |
|
24844 | 0 | 11-30 |
귀한 정보와 좋은 강좌,,,
고맙습니다.