윈 도 우 USB에서 win7 사용하기
2010.10.31 01:06
스누피님의 'USB에 win7 설치하기'나
우금티님의 snapshot.exe 혹은 Hyper-V에 설치한 이미지를 이용하는 방법이 있지만
약간 다르게 USB에서 win7 사용하는 방법에 관한 글이 있어서 소개합니다.
원문링크: https://www.boot-land.net/forums/index.php?s=bb22e75502f16ddc5909e181bf273a8a&showtopic=9196
위 글에는 USB 디스크를 직접 사용하는 방법과 VHD를 이용하는 방법 두 가지를 설명하는 데 원리는 같습니다.
이 글에서는 제가 테스트해 본 VHD를 이용한 방법에 관해서만 소개합니다.
1. 하드디스크에 VHD를 만들어 win7을 설치합니다.( 기존에 VHD를 만들어 사용하신다면 그대로 사용하셔도 됩니다.)
2. VHD에 설치한 win7에서 usbbootfix.bat 를 실행한 후
다른 운영체제나 PE로 부팅하여 VHD를 USB에 복사합니다.
3. USB의 파티션에 활성( Active)을 걸어 줍니다.
4. USB안의 VHD를 연결( attach)해서 다음 명령으로 USB에 부팅파일을 만들어 줍니다.
bcdboot.exe k:\windows /l ko-kr /s j:
-? k: 는 VHD 드라이브 문자이고 j: 는 USB의 드라이브 문자입니다.
끝입니다. USB로 부팅하여 테스트 합니다.
<usbbootfix.bat 의 내용>
----------------------------------------------------------------------------------------------------------------
@echo off
if "%1"=="fix" goto :fix
rem -- install task
copy /y "%~f0" "%SystemRoot%\system32\usbbootfix.bat"
SCHTASKS /Create /RU SYSTEM /SC ONEVENT /MO "*[System[Provider[@Name='Microsoft-Windows-UserPnp'] and EventID=20003]]" /EC System /TN USBBootFix /TR "'%SystemRoot%\system32\usbbootfix.bat' fix" /F
rem -- apply other settings
reg add HKLM\SYSTEM\CurrentControlSet\services\pciide /v Start /t REG_DWORD /d 0x0 /f
reg add HKLM\SYSTEM\CurrentControlSet\services\msahci /v Start /t REG_DWORD /d 0x0 /f
reg add HKLM\SYSTEM\CurrentControlSet\services\intelide /v Start /t REG_DWORD /d 0x0 /f
reg add HKLM\SYSTEM\CurrentControlSet\services\viaide /v Start /t REG_DWORD /d 0x0 /f
rem -- run :fix once after install
:fix
call :fixservice usbehci "Boot Bus Extender"
call :fixservice usbohci "Boot Bus Extender"
call :fixservice usbuhci "Boot Bus Extender"
call :fixservice usbhub "System Bus Extender"
call :fixservice usbstor "SCSI miniport"
goto :eof
:fixservice
setlocal
set Start=
set Group=
for /f "skip=2 tokens=1,2,*" %%I in ('reg query HKLM\SYSTEM\CurrentControlSet\services\%~1') do (
if "%%I"=="Start" set Start=%%K
if "%%I"=="Group" set Group=%%K
)
if not "%Start%"=="0x0" reg add HKLM\SYSTEM\CurrentControlSet\services\%~1 /v Start /t REG_DWORD /d 0x0 /f
if not "%Group%"=="%~2" reg add HKLM\SYSTEM\CurrentControlSet\services\%~1 /v Group /t REG_SZ /d "%~2" /f
endlocal
goto :eof
----------------------------------------------------------------------------------------------------------------
주요 내용은
레지스트리에 등록된 하드 디스크 컨트롤러에 관한 서비스 값 중에서 'Start' 값을 0 으로 변경하고
USB에 관련된 서비스 값 중에서 'Start'와 'Group' 값을 0과 'Boot....'으로 변경한 뒤
EventID=20003( 서비스 설치) 가 생기면 위 배치 파일중 USB에 관련된 명령을 실행하게끔
작업 스케줄러에 등록하는 내용입니다.
드라이버를 설치하게 되면
HKLM\SYSTEM\CurrentControlSet\services와 기타 경로에 드라이버 정보를 등록하게 되는데
윈도우가 부팅하면서 이 곳의 레지스트리를 읽어서 드라이버를 로드하는 것 같습니다.
'Start' 값데이타가 0 인 드라이버는 부팅에 필요한 드라이버라는 뜻입니다.
USB 디스크 드라이버의 'Start' 기본값은 3 입니다.
'Group' 값 또한 구체적으로 로딩순서를 정하는 값인데
HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\ServiceGroupOrder 에 로딩순서대로
나열한 'Group' 값이 있습니다.
5. USB에 설치된 win7을 다른 컴퓨터에서 사용하려면 사용할 컴퓨터의 하드 디스크 컨트롤러 드라이버의
'Start' 값을 0 으로 변경한 뒤에 사용합니다.
어떤 드라이버인지 확실히 모를 경우 StorageBootStart.bat 를 실행한 뒤 종료한 다음 사용합니다.
StorageBootStart.bat 는 win7 에 미리 설치된 모든 하드 디스크 컨트롤러 드라이버의 'Start' 값을 0으로 변경시킵니다.
번호 | 제목 | 글쓴이 | 조회 | 추천 | 등록일 |
---|---|---|---|---|---|
[공지] | 강좌 작성간 참고해주세요 | gooddew | - | - | - |
772 | 소프트웨어| pureBasic 외부 함수 호출 [1] | 입니다 | 377 | 9 | 03-25 |
771 | 소프트웨어| pureBasic 구조체, Union 구조체 [4] | 입니다 | 643 | 9 | 03-25 |
770 | 윈 도 우| batch 파일 정복 [9] | gooddew | 6860 | 10 | 09-25 |
769 | 윈 도 우| 윈도우 8 레지스트리 파일 몇개올립니다. [14] | 머스빅 | 16584 | 10 | 11-08 |
768 | 소프트웨어| Win8PEL.iso와 Win7PEL.iso 멀티부팅하기 [16] | suk | 12833 | 10 | 07-27 |
767 | 윈 도 우| diskpart를 갖고 놀아봐요~ [8] | 윈도우찬양 | 20502 | 10 | 05-06 |
766 | 윈 도 우| 가장 쉬운 usb부팅 방법... [12] | 구디 | 19641 | 10 | 10-10 |
765 | 윈 도 우| vhdman으로 vdisk만들고 부팅메뉴 등록하기 [14] | 하늘보기 | 17950 | 10 | 03-31 |
764 | 윈 도 우| Win7PE/Builder를 설정/수정/사용해서/처음사용자 [3] | 까꾸리 | 6887 | 10 | 06-18 |
763 | 소프트웨어| 진짜 쉬운 부팅USB 만들기(2) - PowerISO 사용 [3] | 그루터기 | 11471 | 10 | 08-19 |
762 | 윈 도 우| 윈도우 제품키 없이 토큰 복구 방법 [25] | 희망성사 | 14068 | 10 | 09-21 |
761 | 윈 도 우| [기초편] VHD 만들어서 멀티부팅하기 [12] | suk | 10506 | 10 | 10-09 |
760 | 소프트웨어| 안드로이드폰에서 구동하는 KMS에뮬 [11] | 링고스타 | 14639 | 10 | 11-20 |
759 | 윈 도 우| 윈8.1 파일탐색기에서 "폴더"항목 (내문서,다운... [14] | LazyFlow | 9129 | 10 | 12-03 |
758 | 윈 도 우| XP.VHD를 만들어서 부팅하기 [21] | suk | 13654 | 10 | 01-02 |
757 | 윈 도 우| Gimagex WIM 마운트 하기... (기초 첫 걸음) [12] |
|
9131 | 10 | 05-29 |
756 | 소프트웨어| 유토렌트 uTorrent 3.4.X 에서 광고 차단(제거)하기 [24] |
|
17220 | 10 | 09-20 |
755 | 하드웨어| 인텔 USB 3.0 에 대하여... (내용추가) [21] | 디폴트 | 6632 | 10 | 10-10 |
754 | 윈 도 우| GIMAGEX 로 윈도우 설치하기 [14] | gooddew | 10982 | 10 | 12-14 |
753 | 기 타| 360클라우드_빠른 다운 [22] | 구들목 | 10630 | 10 | 12-28 |
귀한 정보와 좋은 강좌,,,
고맙습니다.