윈 도 우 기본 프린터 확인 및 테스트 페이지 인쇄 batch script
2020.01.19 21:28
아래 레마클로님이 vbscript로 만드신거 올리셨길래 배치파일로도 만들 수 있을거같아서
허접한 실력이지만 만들어 보았습니다
윈도10 제 컴에선 일단 잘 돌아가길래 올려봅니다
고수님들께서 더 간결하고 좋게 수정해주셨으면 좋겠네요
---------------- 스크립트 시작 --------------------
@echo off
setlocal
for /f "tokens=1*" %%a in ('wmic printer get name^,default ^| find "TRUE"') do set pp=%%b&set gg=%%a
if %gg% == TRUE (
echo Default Printer : %pp%
) else (
echo Default Printer not found.
goto END
)
set pp=%pp%##
set pp=%pp: ##=##%
set pp=%pp: ##=##%
set pp=%pp: ##=##%
set pp=%pp: ##=##%
set pp=%pp: ##=##%
set pp=%pp:##=%
set /p YN=Do you want to print a test page[Y/N]?
if %ERRORLEVEL% == 1 goto END
if /i %YN% == Y (
rundll32.exe printui.dll,PrintUIEntry /k /n "%pp%"
) else (
goto END
)
:END
pause
댓글 [5]
-
한돼지 2020.01.19 21:45
-
sua 2020.01.19 22:52
감사합니다
XP에서도 잘 작동 됩니다
-
레마클로 2020.01.19 22:54 원래 아래 배치파일이 원본입니다. 단순히 기본프린터로 테스트페이지 만 인쇄하는 배치파일이죠.
@echo off
pushd %~dp0
setlocal
for /f "tokens=2*" %%a in ('reg query "HKCU\Software\Microsoft\Windows NT\CurrentVersion\Windows" /v Device') do (set DefPRN1=%%b)
for /f "tokens=1 delims=," %%a in ("%DefPRN1%") do set DefPRN=%%a
start RUNDLL32 PRINTUI.DLL,PrintUIEntry /k /n "%DefPRN%"
endlocal
참고하세요.^^
-
컨피그 2020.01.19 23:19
감사합니다~^^
기본 프린터 이름을 레지스트리에서 가져오는게 좋겠네요
저는 기본 프린터 이름을 wmic printer get name,default 명령에서 가져오다보니 이름끝에 공백이 들어가더라고요
이름 뒷부분 공백제거 방법을 몰라서 구글링 한걸로 넣다보니 소스가 지저분해졌네요..
레지스트리에서는 공백없이 깔끔하게 가져올 수 있으니 이 방법이 편하고 좋네요
혹시 그런데 뒷부분 공백제거 방법 제가 쓴 방법 말고 간단한게 있을까요?
-
컨피그 2020.01.22 19:22
레마클로님 소스 적용하고
쓸데없는 부분 걷어내니까 좀 더 간결하고 잘 작동되네요
if문 변수에 쌍따옴표를 넣는것과 안넣는 작은 차이가 로직을 간결하게 해주네요
@echo off
setlocal
for /f "tokens=2*" %%a in ('reg query "HKCU\Software\Microsoft\Windows NT\CurrentVersion\Windows" /v Device') do (set DefPRN1=%%b)
for /f "delims=," %%a in ("%DefPRN1%") do set DefPRN=%%a
echo Default Printer : %DefPRN%
set /p YN=Do you want to print a test page[Y/N]?
if /i "%YN%" == "Y" start rundll32.exe printui.dll,PrintUIEntry /k /n "%DefPRN%"
:END
endlocal
pause
감사합니다
Win10에서 작동 잘 됨니다