기 타 레마클로님 wifi on/off 스크립트 (수정) pnputil 추가

예전에 레마클로님 강좌 팁 중 Wifitoggle 스크립트를 공유해준부분에서

약간 수정해 보았습니다. 메인 스크립트를 누르면 실행 스크립트를

만들어 주는 부분이 있었는데 파일 한개로 통합해 보았습니다.

 

출처:

https://windowsforum.kr/index.php?mid=lecture&search_keyword=wifi&search_target=title_content&document_srl=12789549

다운로드: WifiToggle.zip

 

레마클로님 이 주신 스크립트에서는 devcon.exe 이라든가

qgrep.exe 두개 파일로 WiFi 장치 확인 및 줄 확인을

하여 실행합니다. 최대한 명령줄을 줄여 봤습니다.

 

------------------------------------------------------------

@echo off

type "enable" >nul&&set "toggle=disable"||set "toggle=enable"

del /q "disable", "enable">nul&devcon hwids =net>"devconout"

qgrep -n -y "Wi-Fi wireless" "devconout">"qgrepout"

FOR /F "tokens=1* usebackq delims=:" %%a in ("qgrepout") do set /a WirelessLine=%%a+1&goto:Locate

 

:Locate 

FOR /F "tokens=1* usebackq skip=%WirelessLine% delims=: " %%z in ("devconout") do set WirelessHID="%%z"&goto:Shutdown

 

:Shutdown

devcon %toggle% %WirelessHID%&echo %WirelessHID%>"%toggle%"

del /q "qgrepout", "devconout"

-------------------------------------------------------------

 

이렇게도 가능 하네요

txt 파일을 만들어서 WiFi 가 연결되었는지

확인 다른 프로그램들은 필요가 없음

 

-------------------------------------------------------------

@echo off

type "enable" >nul&&set toggle=disable||set toggle=enable

del /q "disable", "enable">nul&echo.>"%toggle%

netsh interface set interface name="Wi-Fi" admin=%toggle%

--------------------------------------------------------------

 

또다른 방법 기본 프로그램 netsh 사용 txt 파일을

만들지 않고 실행하며. 부가 프로그램 필요 없음

 

-------------------------------------------------------------

@echo off&chcp 437

for /f "tokens=2 delims= " %%a in ('netsh interface show interface ^| findstr "Wi-Fi"') do (

if "%%a"=="Connected" (set toggle=disable) else set toggle=enable)

netsh interface set interface name="Wi-Fi" admin=%toggle%

-------------------------------------------------------------

 

pnputil 추가

zerojiddu 님이 windows 에서는 pnputil 로

해야 잘된다고 하시기에 해봤는데

pnputil 에서는 wifi 활성화 비활성화 구문을

찾기가 어려워 netsh 로 구문을 찾고

pnputil 로 활성화 비활성화를 해보았습니다.

 

-------------------------------------------------------------

@echo off&chcp 437

for /f "tokens=2 delims= " %%a in ('netsh interface show interface ^| findstr "Wi-Fi"') do set connect=%%a

if "%connect%" equ "Connected" (set toggle=Disable) else (set toggle=Enable)

pnputil /enum-devices /class net | findstr /n "^" > pnputil

for /f "delims=:" %%a in ('findstr /c:" Wireless" pnputil') do set /a line=%%a-1

for /f "tokens=3 delims=:" %%a in ('findstr /b "%line%:" pnputil') do for %%b in (%%a) do set "device=%%b"

pnputil /%toggle%-device "%device%"&del /q pnputil

--------------------------------------------------------------

 

pnputil 만으로 한다면 아래와 같습니다.

 

--------------------------------------------------------------

@echo off&chcp 437

pnputil /enum-devices /class net | findstr /n "^" > pnputil

for /f "delims=:" %%a in ('findstr /c:" Wireless" pnputil') do set /a line=%%a-1

for /f "tokens=3 delims=:" %%a in ('findstr /b "%line%:" pnputil') do for %%b in (%%a) do set "device=%%b"

pnputil /enum-interfaces /enabled | findstr /c:"%device%" >nul

if %errorlevel% equ 0 (set toggle=Disable) else (set toggle=Enable)

pnputil /%toggle%-device "%device%"&del /q pnputil

--------------------------------------------------------------