강좌 / 팁

윈 도 우 VHD 부트에서 부팅된 VHD 파일경로 추출과 활용 스크립트

2020.05.31 21:37

Neutrino 조회:1030 추천:7

WTG 등 VHD 부팅에서는 부트환경에 따라 vhd가 있는 드라이브명이 수시로 바뀌지만

윈도우에서는 이를 확인할수 있는 환경변수를 별도로 제공하지 않습니다.

이때 vhd와 함께 portable을 함께 운영하는 경우 부트 환경에 따라 볼륨명이 바뀌어 난처할수 있는데

아래 스크립트는 실제 부트된 vhd 파일의 절대경로를 추출하여 드라이브명으로 Portable 변수를 등록해줍니다.


@echo off
net session >nul 2>&1 && (set previlige=/m &set reg_env="HKLM\SYSTEM\CurrentControlSet\Control\Session Manager\Environment") || (set previlige= &set reg_env=HKCU\Environment)
Call :GET_VHD
If %errorlevel% NEQ 0 Call :Msg %errorlevel% -FAIL- 16 &Goto :EOF
For /f "tokens=3" %%a in ('reg query %reg_env% /v VHD') do (set VHD=%%a)
set Portable=%VHD:~0,2%\Portable& :포터블 위치가 다르면 수정시 공백주의.
setx %previlige% Portable %Portable%
Call :Msg 0 -SUCCESS- 64
Goto :EOF

:GET_VHD
(echo $i=23; $j=20
echo Import-Module %SystemRoot%\DevicePath.psm1
echo If ^^^(-Not $?^^^) {Exit 100}
echo $dev=Get-Disk ^^^| Select-Object Location ^^^|findstr \Device\HarddiskVolume
echo If ^^^(-Not $?^^^) {Exit 101}
echo While ^^^($dev.SubString^^^($i, 1^^^) -eq '\'^^^) {$i++}
echo $dev1=$dev.substring^^^(0,$i-1^^^)
echo $dev2=$dev.substring^^^($i^^^)
echo $drv=DevicePath ^^^|findstr $dev1
echo If ^^^(-Not $?^^^) {Exit 102}
echo $drv=$drv.replace^^^($dev1, ""^^^).trim^^^(^^^)
echo $VHD=^^^(attrib ^^^($drv + '\' + $dev2^^^)^^^).substring^^^($j^^^).trim^^^(^^^)
echo reg add %reg_env% /v VHD /d $VHD /f ^^^|out-null
) | powershell -ExecutionPolicy bypass -NoLogo
echo.
Exit /b

:Msg
If %1==0 set msg=이 VHD 시스템은 %VHD% 파일로 부팅되었고 이의 값은 환경변수 VHD 와 Portable 에 등록되었습니다.
If %1==100 set msg=DevicePath.psm1 모듈을 %SystemRoot% 위치에 복사후 실행하세요.
If %1==101 set msg=이 시스템은 VHD 부팅된 시스템이 아닌것 같습니다
If %1==102 set msg=죄송합니다. VHD 파일을 추출해내는데 실패했습니다
(echo Add-Type -AssemblyName PresentationCore,PresentationFramework
 echo [System.Windows.MessageBox]::Show^^^('%msg%' ,'%2', 0, %3^^^)
) | powershell >nul
Exit /b

위 내용을 .cmd로 저장후 콘솔창에서 실행 또는 서비스로 등록할수 있습니다.

서비스로 등록하면 부팅후 드라이브가 변경돼도 환경변수 값을 자동으로 갱신해줍니다.

파워쉘 함수가 외부모듈로 작성되어 첨부한 DevicePath.psm1 모듈을 Windows 폴더에 넣어줘야 실행됩니다.

 

먼저 Call :GET_VHD 명령으로 현재 부팅된 .vhd 경로를 추출 %VHD% 환경변수로 저장되며

이어 이 값의 첫자를 잘라 드라이브 문자로 빼서 %Portable% 변수를 조합 등록합니다.

실행시 관리자권한이 있으면 모든 사용자에 적용되는 시스템 변수로 저장되고 아니면 사용자 변수로 저장됩니다.

 

※ CMD에서 테스트후 서비스로 등록할때는 아래쪽 :Msg 블록내의 모든줄을 삭제하고 마지막 Exit/b만 남기면 됩니다.

※ 이 스크립트는  vhd 부트 환경에서 호스트 드라이브에 Portable 폴더를 보관한 경우에 유효합니다.

※ %Portable% 하위함목을 PATH에 추가할때는 set path=%PATH%;%%Portable%%\Programs 처럼 %기호를 두번써야 합니다.

※ Win 7에서는 함수실행 안되므로 사용불가 합니다.

 

바탕화면 또는 탐색기에서 Portable 경로상의 바로가기 생성은  우클릭 ->새로만들기 ->바로가기 순으로 하되 %Portable% 부터 적으면 되며

단 연결 프로그램 설정에서 %Portable% 적용이 직접은 안되고 먼저 바탕화면 같은데에 바로가기를 생성후 이것을 지정하면 잘 됩니다.

번호 제목 글쓴이 조회 추천 등록일
[공지] 강좌 작성간 참고해주세요 gooddew - - -
1601 윈 도 우| 메모리 압축 [11] 내꼬 3210 9 06-30
1600 윈 도 우| 윈도우10 2004 업 후 공유 폴더 접근 네트워크 자격 증명 [2] hanco 3012 7 06-28
1599 윈 도 우| 외국 PE 한글화 하기 [12] gooddew 5804 19 06-25
1598 윈 도 우| Wimboot으로 구성된 시스템 업데이트하는 방법 [4] maniaa 1625 6 06-23
1597 윈 도 우| 나만의 복원 솔루션 만들기 -3부- (UEFI) [15] gooddew 3653 19 06-22
1596 윈 도 우| Windows 10, Administrator 관리자 계정 설치 및 OOBE 오류... [2] 회오리BOi 4552 13 06-21
1595 윈 도 우| 윈도우 디펜더 관리(자동업데이트) [1] 내꼬 3831 6 06-17
1594 윈 도 우| 나만의 복원 솔루션 만들기 -2부- (UEFI) [18] gooddew 4424 29 06-16
1593 윈 도 우| 추가)PE 우측하단 워터마크에 각종 정보 넣기 [14] 히이이잌 2692 24 06-16
1592 윈 도 우| DISM++ 를 이용해서 윈도우 10 설치하기 [18] gooddew 4046 21 06-07
1591 윈 도 우| 나만의 복구 솔루션 만들기 -1부- (UEFI) [36] gooddew 7849 31 06-06
1590 윈 도 우| CMD 배치파일을 로컬 시스템 서비스로 등록 [8] Neutrino 1954 9 06-05
1589 윈 도 우| VHD 동적확장-고정간 변환 및 크기 변경 [1] 신세계 1597 5 06-01
» 윈 도 우| VHD 부트에서 부팅된 VHD 파일경로 추출과 활용 스크립트 [2] Neutrino 1030 7 05-31
1587 윈 도 우| LG 복원 솔류션 이식하기 (UEFI) [14] gooddew 4583 15 05-30
1586 윈 도 우| LG Recovery(UEFI)에 대해서.... [9] 밤이슬216 4459 13 05-25
1585 윈 도 우| 일반 PC 에 삼성 복원 솔루션 이식하기 (UEFI) [54] gooddew 12008 42 05-21
1584 윈 도 우| [팁] 윈도우 탐색기 자동 새로고침에 대한 간단한 팁. [5] 메리아 3768 2 05-19
1583 윈 도 우| SRS7에 대해서..좀 더 자세하게..일반 PC용으로.... [14] 밤이슬216 3447 5 05-18
1582 윈 도 우| SRS8 --- install.wim [5] 밤이슬216 3239 10 05-18
XE1.11.6 Layout1.4.8