Excel 고수님 수정 부탁드립니다.

바로 외출해야해서 귀가 해서 좀 더 보겠습니다.

다음처럼 하면 되는데요. 원본 굵기 정보를 보관합니다.

굵게 된것은 선택이 옮겨가도 여전히 굵게 남을 것이고, 보통은 선택하면 굵게되고 선택이 옮겨가면 원래의 보통으로 돌아갑니다.

그런데 복사 붙여넣기 등 안되는 기능들이 있을텐데 불편하지 않으시겠어요? ^^

필요할때만 잠깐 켜서 사용하시는 방향으로 하심이... ㅎ~

Sub Worksheet_SelectionChange(ByVal Target As Excel.Range)

    myColor = RGB(200, 235, 240)

    Static xRow

    Static xColumn

    Static xBold

    If xColumn <> "" Then

        Columns(xColumn).Interior.ColorIndex = xlNone

        Rows(xRow).Interior.ColorIndex = xlNone

        Cells(xRow, xColumn).Font.Bold = xBold

    End If

    pRow = Selection.Row

    pColumn = Selection.Column

    xRow = pRow

    xColumn = pColumn

    Columns(pColumn).Interior.Color = myColor

    Rows(pRow).Interior.Color = myColor

    With ActiveCell

        .Interior.ColorIndex = xlNone

        xBold = .Font.Bold

        .Font.Bold = True

    End With

End Sub

색상은 연한색으로 다음에서 선택해보십시오. RGB(240, 248, 255) 이렇게 연한색상으로...

셀 배경색은 투명도를 줄 수가 없어서 연한 색상을 선택하면 마찮가지로 투명한 느낌을 줍니다.

https://www.rapidtables.com/web/color/RGB_Color.html

조금 더 느낌을 살려봤습니다. 여기까지만 하겠습니다. ^^

Sub Worksheet_SelectionChange(ByVal Target As Excel.Range)

    myColor = RGB(240, 248, 255)

    Static xRow

    Static xColumn

    Static xBold

    If xColumn <> "" Then

        With Columns(xColumn)

            .Interior.ColorIndex = xlNone

            .Borders.LineStyle = xlNone

        End With

        With Rows(xRow)

            .Interior.ColorIndex = xlNone

            .Borders.LineStyle = xlNone

        End With

        Cells(xRow, xColumn).Font.Bold = xBold

    End If

    pRow = Selection.Row

    pColumn = Selection.Column

    xRow = pRow

    xColumn = pColumn

    With Columns(pColumn)

        .Interior.Color = myColor

        .Borders.Color = RGB(220, 220, 220)

    End With

    With Rows(pRow)

        .Interior.Color = myColor

        .Borders.Color = RGB(220, 220, 220)

    End With

    With ActiveCell

        .Interior.ColorIndex = xlNone

        xBold = .Font.Bold

        .Font.Bold = True

    End With

End Sub

여기 숨은 고수님들이 매우매우 많군요