윈도우 / PE 윈도우 부팅 복구 스크립트

윈도우 7, 8, 8.1, 10 버전에서 사용 가능한 부팅 복구 배치파일을 만들어 보았습니다.

제가 만든 스크립트는 운영체제가 하나만 있을때 유용할듯 합니다.

하드에 여러 운영체제가 있으면 이 스크립트를 사용하는것보다

수작업으로 하시거나 부팅 관련 유틸을 이용하시는것을 권장해 드립니다.

사용 방법은 첨부한 압축 파일을 다운받아서 적당한 위치에서 압축을 풀면 boot_fix 라는 폴더가 생성됩니다..

그 폴더로 들어가면 boot.cmd 배치파일과 boot 폴더 두개가 존재 합니다.

여기서  boot.cmd 를 실행하시면 드라이브 리스트가 나옵니다.

여기서 윈도우가 설치된 부팅을 복구할 드라이브 명(c, d 및 e 등등)을 입력 후 엔터 하시면 됩니다.

여기서 드라이브명 뒤에 콜론은 입력하지 마시고 D 또는 E 이렇게 문자만 넣으시면 됩니다.

만약 C 드라이브라면 그냥 엔터만 치시면 됩니다.

아래는 소스입니다.

-----------------------------------------------------------------------

@echo off
title 부팅 복구 스크립트
pushd %~dp0
echo lis dis > "boot\Script.txt"
echo lis vol >> "boot\Script.txt"
echo exit >> "boot\Script.txt"
diskpart /s "boot\Script.txt"

del "boot\Script.txt" /q

echo.
echo.
set Disk=c
echo. 디스크명을 입력후 엔터를 누르세요. C 드라이브일 경우 엔터만 누르세요.
echo.
set /p Disk=.종료를 원하시면 x(X) 키를 입력후 엔터를 누르세요. [ C ~ Z ] :
echo.

if "%Disk%" == "x" goto exit
if "%Disk%" == "X" goto exit

echo select vol=%Disk% > "boot\Script.txt"
echo act >> "boot\Script.txt"
echo exit >> "boot\Script.txt"
diskpart /s "boot\Script.txt"

del "boot\Script.txt" /q

boot\bootsect /nt60 %Disk%: /mbr

boot\bcdboot %Disk%:\windows /s %Disk%: /l ko-kr

:exit