윈 도 우 윈도우7!!!!!에서 탐색기에 크기 항목에 파일뿐만 아니라 폴더 크기도 표시하기

제가 원하는 화면이 위 화면과 같은 상태입니다. 탐색기에 폴더 사이즈 항목에 파일과 폴더의 크기가 표시됩니다.

이 스샷은 '폴더 사이즈' 프로그램을 적용 시킨 화면입니다. 하지만 유감스럽게 이 프로그램은 윈도우7에는

적용이 안됩니다. ㅠㅠ 윈도우7에서도 탐색기에서 폴서 크기 알 수 있는 방법이 없나요???

저도 구글로 검색하면서 답을 구하고 있었는데 어느분이 스크립트로 할수 있다고 글을 올려 주셨는데 어떻게 적용하는지

모르겠습니다. 혹시 이걸 어떻게 적용하는지 해석해 주실수 있나요??

----------------------------------------------퍼온 댓글-------------------------------------------------------------

For those who like to roll their own,  this VB Script code will work with Windows 7 and show a simple list with folders and sizes from a cmd prompt.  You can specify the depth.  It's very fast.  Run with no parameters for instructions.

' ====================================================================

' DirSize7.vbs

' Used to display dir sizes in Windows 7 or XP.

'

' To Use:  cscript DirSize7.vbs C:\temp 4

'     Where:

'       First parm  = The dir to start with (default = script dir)

'       Second parm = number of child dirs to display (default = 4)

'

' 2010/7/20 - Tom Woodgerd - Upgraded from DirSizeXP.  Added code to handle folders with no access.

' ====================================================================

option explicit         ' Require declaration of variables.

Dim arrArgs

Dim strTopDir

Dim numDepth

Dim iii

Dim strEOL

Dim strTab

Dim ws

Dim fso

Dim strFolder

Dim arrFolderCollection1

Dim arrFolderCollection2

Dim arrFolderCollection3

Dim arrFolderCollection4

Dim strDisp

Dim strF1

Dim strF2

Dim strF3

Dim strF4

Dim strRootFolder

Dim int_strF1Size

Set ws = WScript.CreateObject ("Wscript.Shell")

strEOL = chr(10) & chr(13)

strTab = chr(9)

Set fso = CreateObject("Scripting.FileSystemObject")

' ---------------  Get command line arguments.

Set arrArgs = WScript.Arguments

' --------- Get folder from command line or if none, the script dir.

If arrArgs.Count > 0 Then

  strTopDir = arrArgs(0)

Else

  strTopDir = fso.GetParentFolderName(Wscript.ScriptFullName)

End If

' --------- Get depth from command line or default = 4.

If arrArgs.Count > 1 Then

  numDepth = arrArgs(1)

  If numDepth > 4 Then

    numDepth = 4

  End If

Else

  numDepth = 4

End if

If arrArgs.Count > 0 Then

  WScript.Echo "====================================================================++======"

  WScript.Echo "DirSize7:          Starting From: " & strTopDir & "    Depth = " & numDepth

  WScript.Echo ""

  WScript.Echo "=========================================================(Ver 7/20/2010)===="

Else

  WScript.Echo "======================================================================++===="

  WScript.Echo "DirSize7:          Starting From: " & strTopDir & "    Depth = " & numDepth

  WScript.Echo ""

  WScript.Echo "     Useage: cscript dirsize7.vbs D:\temp 3"

  WScript.Echo "     Where:"

  WScript.Echo "       Starting Directory = D:\temp"

  WScript.Echo "       Deepest folder to display = 3 (up to 4 max)"

  WScript.Echo ""

  WScript.Echo "==========================================================(Ver 7/20/2010)==="

End If

' --------- Main Loop ---------------------------------------------

Set strFolder = fso.GetFolder(strTopDir)

If Not strFolder.IsRootFolder then

  int_strF1Size = 0

  On Error Resume Next

  int_strF1Size = strFolder.size

  If int_strF1Size = 0 then       '--- See if we have access.

    WScript.Echo "----No Access---- "  & strFolder

    WScript.quit

  Else

    WScript.Echo f_AddCommas(strFolder.size), " "& strFolder

  end if

End If

Set arrFolderCollection1 = strFolder.SubFolders

For Each strF1 in arrFolderCollection1

  int_strF1Size = 0

  On Error Resume Next

  int_strF1Size = strF1.size

  If int_strF1Size = 0 then       '--- See if we have access.

    WScript.Echo " ----No Access---- "  & strF1

  Else

    WScript.Echo f_AddCommas(strF1.size), " "& chr(28)&" "& strF1

    If numDepth >= 2 Then '----------------------------- Start of 2nd level

      Set strFolder = fso.GetFolder(strF1)

      Set arrFolderCollection2 = strFolder.SubFolders

      For Each strF2 in arrFolderCollection2

        WScript.Echo f_AddCommas(strF2.size), "  "& chr(28)&" "& strF2

        If numDepth >= 3 Then '----------------------- Start of 3rd level

          Set strFolder = fso.GetFolder(strF2)

          Set arrFolderCollection3 = strFolder.SubFolders

          For Each strF3 in arrFolderCollection3

            WScript.Echo f_AddCommas(strF3.size), "   "& chr(28)&" "&  strF3

              If numDepth >= 4 Then '----------------- Start of 4th level

                Set strFolder = fso.GetFolder(strF3)

                Set arrFolderCollection4 = strFolder.SubFolders

                For Each strF4 in arrFolderCollection4

                  WScript.Echo f_AddCommas(strF4.size), "    "& chr(28)&" "&  strF4

                Next

              End If '--------------------------------- End of 4th level

            Next

        End If '----------------------------------- End of 3rd level

      Next

    End If ' ---------------------------------- End of 2nd Level

  End if

Next

' -------------------------- Format a numeric string with commas

Function f_AddCommas(parmStr)

  Dim strTemp

  ' ---- Drop the ".00"

  strTemp = left(formatcurrency(parmStr), Instr(formatcurrency(parmStr), ".")-1 )

  strTemp = mid(strTemp,2)  ' Drop the $

  f_AddCommas = space(15-len(strTemp)) & strTemp

End Function

-----------------------------------------------------------여기까지----------------------------------------------------

출처 : https://social.technet.microsoft.com/Forums/en/w7itproui/thread/ce998316-c210-4cdb-a38b-69be223a305f

우선 메모장으로 읽어서 모든파일 형식으로 vbs로 저장해서 명령프로토콜로 열어서 적용하는게 맞는지요??