기 타 파일명을 폴더명대로 일괄 변경 배치파일 알려주실 수 있나요?

이정도는 배치파일 안짜고도 가능합니다

폴더내 파일 전체선택 - 우클릭 - 이름 바꾸기 - 폴더이름 입력

이러면 폴더내 파일 이름 다 바껴요

파워쉘[관리자] 열고 저거 치면,

하위 모든 폴더 파일까지 개수와 관계없이 한꺼번에 다 바뀝니다.

기존 폴더명은 그대로 있고,

각파일 이름이 사진파일이 들어있는 <폴더명-순차적 숫자> 로 바껴집니다.

먼저, 이름변경때 윈도우 260자 긴 이름제한 에러방지 레지스트리키 변경해주시고요.

New-ItemProperty -Path "HKLM:\SYSTEM\CurrentControlSet\Control\FileSystem" -Name "LongPathsEnabled" -Value 1 -PropertyType DWORD -Force -verbose

이제, 일괄 이름변경

$i=1; get-childitem -recurse -ea SilentlyContinue | ?{$_.Psiscontainer -eq $false} | %{Rename-Item $_.Fullname -NewName ($_.Directory.Name + "-" + '{0}' -f $i++ +$_.extension) -force -ea ignore -verbose}

* 사진파일이 들어있는 폴더위치로 파워쉘 상에서 이동후 치시면 됩니다.

제가 즐겨 사용하는 방법은 

DarkNamer 라는 프로그램을 이용하여

1.이름 지우기 → 파일명이 확장자 빼고 지워짐

2.경로명 앞에 → 폴더명 추가됨

3.번호붙이기 → 폴더명 앞,또는 뒤에 시리얼 번호 삽입(자리수는 사용자 지정)

이렇게 하면 간단히 파일명 바꿀수 있습니다.

토탈 커맨더 "일괄 이름변경 도구" = Multi-Rename Tool 에서 다음처럼 하면 쉽게 가능합니다.

언더바 "_", 자리 숫자를 조절하면 원하시는 결과를 쉽게 얻을 수 있을 것 같습니다.

배치 파일로 한다면 다음과 같습니다. rename2parent.cmd 배치파일을 해당 폴더에 복사후 실행하십시오.

@echo off & cd /d "%~dp0" & setlocal enabledelayedexpansion

for %%a in ("%~dp0.") do set "dir_name=%%~nxa"

choice /m "'%dir_name%' 폴더내의 모든 jpg 파일을 '%dir_name%_0001.jpg' 형태로 바꾸시겠습니까?"

if %errorlevel%==2 echo 취소하였습니다. & timeout 3 & endlocal & exit /b

for /f "tokens=*" %%a in ('dir *.jpg /b') do (

set /a i+=1 & set #=000!i!& set #=!#:~-4!

ren "%%a" "%dir_name%_!#!%%~xa")

echo 완료하였습니다. & timeout 3 & endlocal & exit /b

원하시던 것이라 하셔서 좀 더 업데이트 하였습니다. ^^

- 위에 것은 해당 폴더에 배치파일을 넣고 실행해야 해서 폴더가 많을 때는 불편함이 있습니다.

- rename2parent.cmd 이 것은 기본적으로 위와 같은 방식으로 실행할 수 있고, 추가로 sendto 에 넣어두고

- 탐색기에서 해당 폴더를 우클릭하여 보내기 아래의 rename2parent.cmd 을 실행하는 방식으로 사용할 수 있습니다.

- 해당 폴더에만 적용되기 때문에 필요시 서브 폴더는 각각 추가로 실행해줘야 합니다.

- sendto 폴더 쉽게 여는 방법은 win+r 실행 shell:sendto 입력후 실행합니다.

@echo off & setlocal enabledelayedexpansion

if [%1]==[] (set dir_path=%~dp0) else (set dir_path=%~1)

if exist "%dir_path%\*" (cd /d "%dir_path%") else echo %1 폴더가 존재하지 않습니다. & goto end

for %%a in ("%cd%\.") do set "dir_name=%%~nxa"

choice /m "'%dir_name%' 폴더내의 모든 jpg 파일을 '%dir_name%_0001.jpg' 형태로 바꾸시겠습니까?"

if %errorlevel%==2 echo 취소하였습니다. &  goto end

for /f "tokens=*" %%a in ('dir *.jpg /b') do (set /a i+=1 & set #=000!i!& set #=!#:~-4!

ren "%%a" "%dir_name%_!#!%%~xa")

echo %i% 개의 파일 이름을 변경하였습니다.

:end

timeout 3 & endlocal & exit /b

ps. 테스트가 충분치 않습니다. 오류 있으면 댓글 주십시오. ^^