윈 도 우 VHD 부트에서 부팅된 VHD 파일경로 추출과 활용 스크립트
2020.05.31 21:37
WTG 등 VHD 부팅에서는 부트환경에 따라 vhd가 있는 드라이브명이 수시로 바뀌지만
윈도우에서는 이를 확인할수 있는 환경변수를 별도로 제공하지 않습니다.
이때 vhd와 함께 portable을 함께 운영하는 경우 부트 환경에 따라 볼륨명이 바뀌어 난처할수 있는데
아래 스크립트는 실제 부트된 vhd 파일의 절대경로를 추출하여 드라이브명으로 Portable 변수를 등록해줍니다.
@echo off
net session >nul 2>&1 && (set previlige=/m &set reg_env="HKLM\SYSTEM\CurrentControlSet\Control\Session Manager\Environment") || (set previlige= &set reg_env=HKCU\Environment)
Call :GET_VHD
If %errorlevel% NEQ 0 Call :Msg %errorlevel% -FAIL- 16 &Goto :EOF
For /f "tokens=3" %%a in ('reg query %reg_env% /v VHD') do (set VHD=%%a)
set Portable=%VHD:~0,2%\Portable& :포터블 위치가 다르면 수정시 공백주의.
setx %previlige% Portable %Portable%
Call :Msg 0 -SUCCESS- 64
Goto :EOF
:GET_VHD
(echo $i=23; $j=20
echo Import-Module %SystemRoot%\DevicePath.psm1
echo If ^^^(-Not $?^^^) {Exit 100}
echo $dev=Get-Disk ^^^| Select-Object Location ^^^|findstr \Device\HarddiskVolume
echo If ^^^(-Not $?^^^) {Exit 101}
echo While ^^^($dev.SubString^^^($i, 1^^^) -eq '\'^^^) {$i++}
echo $dev1=$dev.substring^^^(0,$i-1^^^)
echo $dev2=$dev.substring^^^($i^^^)
echo $drv=DevicePath ^^^|findstr $dev1
echo If ^^^(-Not $?^^^) {Exit 102}
echo $drv=$drv.replace^^^($dev1, ""^^^).trim^^^(^^^)
echo $VHD=^^^(attrib ^^^($drv + '\' + $dev2^^^)^^^).substring^^^($j^^^).trim^^^(^^^)
echo reg add %reg_env% /v VHD /d $VHD /f ^^^|out-null
) | powershell -ExecutionPolicy bypass -NoLogo
echo.
Exit /b
:Msg
If %1==0 set msg=이 VHD 시스템은 %VHD% 파일로 부팅되었고 이의 값은 환경변수 VHD 와 Portable 에 등록되었습니다.
If %1==100 set msg=DevicePath.psm1 모듈을 %SystemRoot% 위치에 복사후 실행하세요.
If %1==101 set msg=이 시스템은 VHD 부팅된 시스템이 아닌것 같습니다
If %1==102 set msg=죄송합니다. VHD 파일을 추출해내는데 실패했습니다
(echo Add-Type -AssemblyName PresentationCore,PresentationFramework
echo [System.Windows.MessageBox]::Show^^^('%msg%' ,'%2', 0, %3^^^)
) | powershell >nul
Exit /b
위 내용을 .cmd로 저장후 콘솔창에서 실행 또는 서비스로 등록할수 있습니다.
서비스로 등록하면 부팅후 드라이브가 변경돼도 환경변수 값을 자동으로 갱신해줍니다.
파워쉘 함수가 외부모듈로 작성되어 첨부한 DevicePath.psm1 모듈을 Windows 폴더에 넣어줘야 실행됩니다.
먼저 Call :GET_VHD 명령으로 현재 부팅된 .vhd 경로를 추출 %VHD% 환경변수로 저장되며
이어 이 값의 첫자를 잘라 드라이브 문자로 빼서 %Portable% 변수를 조합 등록합니다.
실행시 관리자권한이 있으면 모든 사용자에 적용되는 시스템 변수로 저장되고 아니면 사용자 변수로 저장됩니다.
※ CMD에서 테스트후 서비스로 등록할때는 아래쪽 :Msg 블록내의 모든줄을 삭제하고 마지막 Exit/b만 남기면 됩니다.
※ 이 스크립트는 vhd 부트 환경에서 호스트 드라이브에 Portable 폴더를 보관한 경우에 유효합니다.
※ %Portable% 하위함목을 PATH에 추가할때는 set path=%PATH%;%%Portable%%\Programs 처럼 %기호를 두번써야 합니다.
※ Win 7에서는 함수실행 안되므로 사용불가 합니다.
바탕화면 또는 탐색기에서 Portable 경로상의 바로가기 생성은 우클릭 ->새로만들기 ->바로가기 순으로 하되 %Portable% 부터 적으면 되며
단 연결 프로그램 설정에서 %Portable% 적용이 직접은 안되고 먼저 바탕화면 같은데에 바로가기를 생성후 이것을 지정하면 잘 됩니다.
댓글 [2]
번호 | 제목 | 글쓴이 | 조회 | 추천 | 등록일 |
---|---|---|---|---|---|
[공지] | 강좌 작성간 참고해주세요 | gooddew | - | - | - |
4368 | 윈 도 우| 프로그램 필요없이, 윈도우 설치 USB 만들기 [16] |
|
5694 | 27 | 01-18 |
4367 | 윈 도 우| WIM(PE) 1회성 부팅; 우클릭 보내기 메뉴에 추가 [16] | 지후빠 | 2685 | 27 | 02-11 |
4366 | 소프트웨어| 엑셀 추가기능; Reading Layout(셀 좌표) 1.4 [25] | 지후빠 | 2152 | 27 | 11-18 |
4365 | 소프트웨어| ventoy.json 꿀팁-1 [12] | 메인보드 | 6404 | 27 | 06-17 |
4364 | 소프트웨어| PE.WIM DPI%, IconSize 변경 배치! [15] | 무월 | 1904 | 27 | 01-11 |
4363 | 윈 도 우| PE 수정 스크립트 V3.87 [12] | 히이이잌 | 2629 | 27 | 12-20 |
4362 | 기 타| [팁] PE에서 wim 부팅하는데 필요한 boot.sdi [12] | suk | 3765 | 27 | 04-24 |
4361 | 윈 도 우| [정리] 인텔 cpu 보안 패치파일 정리해봤습니다 [32] | suk | 6370 | 27 | 01-09 |
4360 | 윈 도 우| 드라이브스넵샸 자동백업및복구 [56] | 난이나팔자 | 8247 | 27 | 02-17 |
4359 | 윈 도 우| 나만의 PE를 만들자 실전편 3탄 PE고수되기1편 (윈도우10PE... [97] | 지연서연아 | 8695 | 27 | 09-01 |
4358 | 소프트웨어| Office Deployment Tool (ODT) 를 배워봅시다. [26] | 디폴트 | 9906 | 27 | 10-29 |
4357 | 소프트웨어| 오브젝트독(Object Dock) 이용하기 - (본문 수정) [37] | 고양이2 | 5837 | 27 | 12-07 |
4356 | 소프트웨어| (2013.11.09) 수정본 다시 보내드렸습니다 [112] | 고양이2 | 9916 | 27 | 11-08 |
4355 | 소프트웨어| 【PE】Win10XPEooo 빌더로 초간편 PE만들기 [17] | qnd | 3135 | 27 | 08-13 |
4354 | 소프트웨어| PECMD CMPA 복호화 [13] | sunshine | 1463 | 26 | 11-15 |
4353 | 소프트웨어| 오프라인 윈도우 드라이버 백업 [10] | 카멜 | 1625 | 26 | 02-29 |
4352 | 윈 도 우| [3탄] PE빌드를 위한 누적 업데이트 통합 (Winre.wim + ins... [14] | 무월 | 1297 | 26 | 08-25 |
4351 | 소프트웨어| WinNTSetup 윈도우7 VHD 설치 [19] | 무월 | 2003 | 26 | 03-06 |
4350 | 소프트웨어| 단순한 팝업 메뉴형 런처 PopSel (실컴,PE) [18] | 지후빠 | 2461 | 26 | 03-30 |
4349 | 윈 도 우| 구글 검색 결과를 가장한 리다이렉션 광고 링크 제거하기 (... [11] | 오호라7 | 4087 | 26 | 02-26 |
안녕하세요~ 제가 찾던 내용 같은데요.. 잘 이해가 안되서 질문 좀 드릴께요..
usb에 vhd를 넣어서 데탑이나 노트북에서 부팅용으로 활용하고 있습니다.
Usb에 vhd 와 포터블 프로그램을 넣어서 vhd 윈도우 부팅시 어느컴퓨터에서든 포터블 프로그램을 연결해 쓸려고 하는데요
내장 디스크가 1~3개인 컴퓨터도 있다보니.. vhd를 품은 볼륨명이 계속 바뀌어 고정 드라이브(B)로 할려고 합니다.
적어주신 내용이 저와 맞는것 같은데.. 어떻게 하면 될까요?
내용을 다 적어주신거 같은데 이해를 못하겠네요...
밥상 차려주셨는데 밥까지 떠먹여 달래서 죄송합니다..