윈 도 우 IP 변경 배치파일 문의 드립니다.
2019.07.09 11:38
해당 배치 구문에서 ABC는 미리 지정하고 D 부분만 입력해서 IP를 입력하고자 하는데 어떻게 수정을 해야 할까요?
ex) 192.168.0.100
set octetA=%%a
set octetB=%%b
set octetC=%%c
set octetD=%%d
--------------------------------------------------------
@echo off
title Auto_IP_Setting v0.4 - Windowsforum.kr
cls
setLocal enableDelayedExpansion
for /f "tokens=2 delims==" %%F in ('wmic nic where "NetConnectionStatus=2 and AdapterTypeId=0" get NetConnectionID /format:list') do set interfaceName=%%F
echo.
echo.. 인터페이스 이름 : %interfaceName%
if not %ERRORLEVEL% == 0 goto exit
set RAN_NAME=%interfaceName%
set DNS1=168.126.63.1
set DNS2=168.126.63.2
set SNNum=255.255.255.0
set GWNUM=
set SN=
echo.
set /p IPNum=. 아이피번호를 입력 :
@echo off
for /f "tokens=1-4 delims=. " %%a in ("%IPNum%") do (
set octetA=%%a
set octetB=%%b
set octetC=%%c
set octetD=%%d
)
echo.
set /p sn=. 서브넷 마스크를 입력(255.255.255.0 아닐 경우에 입력) :
if "%SN%"=="" goto gw
if not "%SN%"=="" goto sn
:sn
set SNNum=%SN%
:gw
set GWNum=%octetA%.%octetB%.%octetC%.254
echo.
set /p GWNum=. 게이트 웨이를 입력(%GWNum% 아닐 경우에 입력) :
echo.
echo.
echo.. 네트워크 설정중 입니다. 잠시만 기다리세요.....
netsh interface ipv4 set dnsservers "%RAN_NAME%" static %DNS1% primary > nul
netsh interface ipv4 add dnsservers "%RAN_NAME%" %DNS2% > nul
netsh interface ipv4 set address "%RAN_NAME%" static %IPNum% %SNNum% %GWNum%
echo.. 네트워크 설정이 완료 되었습니다.
echo.
:exit
pause
댓글 [2]
-
컨피그 2019.07.09 12:38
-
Ghost-™ 2019.07.09 13:40 잘 되네요 감사합니다. ^^
@echo off
for /f "tokens=1-4 delims=. " %%a in ("%IPNum%") do (
set octetA=%%a
set octetB=%%b
set octetC=%%c
set octetD=%%d
)
위 부분을 지우고 아래걸로 대체
set octetA=192
set octetB=168
set octetC=0
set /p octetD=. 아이피 끝자리를 입력 :
set IPNum=%octetA%.%octetB%.%octetC%.%octetD%
확인은 안해봤지만..