소프트웨어 ● pe용 boot.wim멀티 부트메뉴 간단등록)winpe64.iso 압축해제 \sources\boo...

● pe용 boot.wim멀티 부트메뉴 간단등록)winpe64.iso 압축해제

\sources\boot.wim 디랙토리 파일위치에 멀티메뉴 간단 등록 boot,bat 파일

사용방법>

Win10PE_x64.iso 라면  압축해제 \sources\boot.wim 디랙토리 파일위치에

boot.bat 만 복사 멀티 부트메뉴 등록가능 합니다.(windows11 ,winpe64에서 등록 가능)

윈포럼에서 많은 분이 iso winpe를  제공하기에 간단히 멀티 등록  실행및 bcdboot 복구 가능 합니다.

주)boot.bat 파일변경시 등록 불가능 합니다

파일조건

bat파일 메인 화면

1. 부트메뉴에 등록

2. 부트메뉴 리스트 

3. cmd창 실행 및 삭제명령

4. d:\BOOTICEx64_KO.exe 이용   d:\EasyBCD_2.4_단일버전.exe 이용

▶ d:\PE\boot.bat  소스 정보

[code=bat]@prompt $s
@color 1f
@cd /d %~dp0
@title %~dp0%~n0.wim 등록을 위하여 %~dp0%~n0.bat 이름이 동일해야 각각드라이브root에boot.sdi복사 합니다
@mode con cols=80 lines=45
@setlocal enabledelayedexpansion
@reg query HKU\S-1-5-20>nul || (PowerShell start -verb runas '%0'&exit)
:sel
@echo.
@echo.        .winpe64 boot.wim 멀티메뉴 등록.(https://11q.kr)
@echo.------------------------------------------------------------
@echo. winpe64 조건에서 (boot.wim,boot.sdi) 부팅 구성 가능 합니다.
@echo. \Win10XPE..\sources\boot.wim ,\Win10XPE..\sources\boot.bat 실행조건
@echo. \Win10XPE..\boot\boot.sdi 를 root에 복사(c:\ d:\ root위치)
@echo. 어느 디랙토리/폴더 boot.bat 실행 하면 boot.wim 등록 합니다.
@echo. winpe64.iso 압축해제후 폴더 \sources\boot.bat에 복사 실행하면 등록 가능.
@echo.============================================================
@echo. 등록준비)boot.bat,boot.wim,boot.sdi 3개 파일
@echo.============================================================
@echo. 조건 1)%~dp0%~n0.wim 와 %~d0\%~n0.sdi 파일이 있어야 정상부팅
@echo.============================================================
@echo. 조건 2)%~dp0%~n0.bat 와 %~dp0%~n0.wim 동일이름 이면 ok 
@echo.-----------------주)불필요시 상위설명 삭제------------ 
@echo.============================================================
@echo. 메뉴등록)%~dp0%~n0.wim 등록(bat파일과=wim파일 동일이름 ok)
@echo.============================================================
@copy %~d0\%~n0.sdi %~dp0%~n0.sdi
@echo.%~d0\%~n0.sdi %~dp0%~n0.sdi 로.sdi파일 복사진행
@echo.------------------------------------------------------------
@copy %~dp0%~n0.sdi %~d0\%~n0.sdi
@echo.%~dp0%~n0.sdi %~d0\%~n0.sdi 로.sdi파일 복사진행       
@echo.=============================================================
@echo. 
@echo.1. 부트메뉴에 등록 (%~dp0%~n0.wim)
@echo. 
@echo.2. 부트메뉴 리스트 (%~dp0%~n0.wim) 최근등록 확인
@echo.
@echo.3. cmd창 실행 및 삭제명령(EasyBCD_이용추천)참조 
@echo.
@echo.4. d:\BOOTICEx64_KO.exe 이용
@echo.   d:\EasyBCD_2.4_단일버전.exe 이용
@echo.
@echo.5. 종료
@echo.------------------------------------------------------------
@echo.Enter...copy %~dp0%~n0.sdi %~d0\%~n0.sdi..복사 합니다
@echo.============================================================
@echo.
@set sel=
@set /p sel=선택하세요: 
@if "%sel%"=="1" goto :1
@if "%sel%"=="2" goto :2
@if "%sel%"=="3" goto :3
@if "%sel%"=="4" goto :4
@if "%sel%"=="5" goto :5
@cls
@goto sel
:1
if exist %~dp0%~n0.wim if exist %~d0\%~n0.sdi goto :start
rem if exist %~dp0%~n0.wim if exist %~dp0%~n0.sdi goto :start
@echo.
@echo.
@echo.============================================================
@echo. %~dp0%~n0.wim와 %~d0\%~n0.sdi 둘다 필요합니다
@echo.============================================================
@echo.     
@pause
@exit
:start
REM bcdedit /create {ramdiskoptions} /d "Recovery" || bcdedit /set {ramdiskoptions} description "Recovery"
bcdedit /create {ramdiskoptions} /d "%~dp0%~n0.wim" || bcdedit /set {ramdiskoptions} description "%~dp0%~n0.wim"
bcdedit /deletevalue {ramdiskoptions} description
bcdedit /set {ramdiskoptions} ramdisksdidevice partition=%~d0
bcdedit /set {ramdiskoptions} ramdisksdipath \boot.sdi
for /f "tokens=1-5 delims=-" %%a in ('bcdedit /create /d "%~dp0%~n0.wim" /application osloader') do (
    set first=%%a
    set last=%%e
    set guid=!first:~-9!-%%b-%%c-%%d-!last:~0,13!
)
bcdedit /set %guid% device ramdisk=[%~d0]%~p0%~n0.wim,{ramdiskoptions}
bcdedit /set %guid% osdevice ramdisk=[%~d0]%~p0%~n0.wim,{ramdiskoptions}
set bios=exe
bcdedit /enum {bootmgr} | findstr /i bootmgfw.efi && set bios=efi
bcdedit /set %guid% path \Windows\system32\boot\Winload.%bios%
bcdedit /set %guid% locale Ko-KR
bcdedit /set %guid% inherit {bootloadersettings}
bcdedit /set %guid% systemroot \Windows
bcdedit /set %guid% nx OptIn
bcdedit /set %guid% detecthal yes
bcdedit /set %guid% winpe yes
bcdedit /set %guid% nointegritychecks yes
bcdedit /displayorder %guid% /addlast
@echo.
@echo.============================================================
bcdedit /enum %guid%
@echo.
@echo.
@echo.============================================================
@echo. 멀티boot menu에 %~dp0%~n0.wim 등록 진행 완료했습니다
@echo.============================================================
@echo. 엔터.....메인메뉴로 이동합니다....
@pause
@goto sel
:2
@echo.
@echo.list
@echo.============================================================
echo on
CMD /c  "bcdedit"
@echo.============================================================
@echo 상기 마지막id가 최근 등록 BCDboot입니다 [복사하여 삭제시 활용하세요]
@echo ---------------------------------------------------------------
@echo.  엔터.....메인메뉴로 이동합니다....
@echo.============================================================
@pause
@goto sel
:3
@echo.
@CMD /c  "bcdedit"
@echo.============================================================
@echo. cmd창 실행 및 삭제명령
@echo.============================================================
@echo 리스트보기 ] bcdedit // 삭제 명령도움말 bceedit /? delete
@echo 삭제명령 예] bcdedit /delete {9515594b-701c-11ec-b6d7-a434d9996ebf}
@echo. bcdedit /delete {ID}
@echo ---------------------------------------------------------------
@echo 상기 마지막id가 최근 등록입니다 [복사하여 삭제시 활용하세요]
@echo.===============================================================
@start cmd.exe
@start cmd.exe
@echo. ..........엔터.....메인메뉴로 이동합니다....
@echo.===============================================================
@pause
@goto sel
:4
@echo.
@echo. 실행 d:\BOOTICEx64_KO.exe  종료후 d:\EasyBCD_2.4_단일버전.exe 실행됩니다
@echo. ..........실행 종료후 엔터..............
@echo ---------------------------------------------------------------
@CMD /c  "d:\BOOTICEx64_KO.exe"
@CMD /c  "d:\EasyBCD_2.4_단일버전.exe"
@echo.===============================================================
@echo. ..........엔터.....메인메뉴로 이동합니다....
@echo.===============================================================  
@pause
@goto sel
:5
@echo.
@echo.exit
@echo.===============================================================
@echo. 즐거운 하루 되세요.....
@echo.===============================================================
@echo.  exit..종료 합니다.....   
@pause
exit
[/code]

...end...