윈 도 우 배치파일 일정 기간 지난 폴더 삭제방법????

forilfes /d 옵션을 써보세요

테스트.cmd  <-- 테스트 해보세요

파일 이름에 나온 날짜를 기준으로 다음처럼 할 수 있을 것 같습니다. 테스트 먼저 해보시길 바랍니다.

1. 배치파일, 관리자 권한으로 실행해야 할 수도 있습니다. 테스트 후 echo rd 부분에서 echo를 지우시면 됩니다.

@echo off &cd /d "%~dp0" & setlocal enabledelayedexpansion

for /d %%a in (*) do (set ymd=%%a

call :DateDiff !ymd:~8,4!/!ymd:~12,2!/!ymd:~14,2! farfrom

if !farfrom! gtr 30 echo rd /q/s %%a

)

pause&exit

:DateDiff

for /f "skip=3 delims=" %%a in ('cscript datediff.vbs %~1') do set %~2=%%a

goto :eof

2. 같은 폴더에 datediff.vbs 도 만들어 두셔야 합니다.

If WScript.Arguments.Count = 0 Then WScript.Quit

CreateObject("Scripting.FileSystemObject").GetStandardStream(1).WriteLine DateDiff("d",WScript.Arguments.Item(0),Now)

많은 분들의 답변 감사합니다. 현제 이리저리 하다가 이코드가 가장 효과적인것 같아서 적용해볼까 합니다. 만. 

문제가 같은날 2개의 폴더가 만들어진다면. 뭐 어쩔 수 없는거죠 뭐 ㅠㅠ;;; 

forfiles /p "d:\test" /s /m * /d -4 /c "cmd /c rmdir /S /Q @path"

많은 곳에서 알려주는 코드 중에서 꼬져님도 알려주신것 중 요부분이 있는데 /S가 붙어버리니 하위폴더까지 확인을 하여

날짜를 확인해버리니 문제가 생겨서 

forfiles /p "d:\test" /m * /d -4 /c "cmd /c rmdir /S /Q @path"

/s를 빼고 하니 현재 만들어진 폴더 기준으로 -4일 전의 폴더를 삭제를 하더군요 에휴.. 어쩔 수 없이 이렇게 해야할 듯 합니다. 

도움을 주신 많은 분들 감사합니다. 

날짜 기준으로 보입니다만, 질문 마지막에는 30개 갯수를 말씀하셔서 참고로 올립니다

현재 기준으로 30개 갯수가 보존되기를 원하시면 윈도우 내장 명령 dir 과 for 구문으로 가능합니다

36개 폴더를 1초 간격으로 만들었습니다.

참고로 (지나가는 이야기) 한꺼번에 복사/붙여넣기로 폴더를 한순간에 만드니까, 삭제할 때 약간 폴더 시간 순서를 헷갈려하더군요

위와 같이 비교적 간단한 for 구문으로 최신 폴더 30개 남겨두고

그 전에 먼저 만들어진 폴더 6개 중에서는 최신 순으로 삭제가 되었습니다

위에 스샷에서 사용한 for 구문입니다.

다시 씁니다만, 날짜와 관계없이, 최신 폴더 30개 남겨두고 오래된 폴더를 삭제하는 구문입니다 [날짜는 수정한 날짜 기준입니다]

for /f "skip=30 tokens=*" %%a in ('dir /ad /b /o-d "E:\Backup\BD_DATA_*"') do rd /q /s "E:\Backup\%%a"

참고로, 위에 수정한 날짜 기준이 혹시 폴더가 수정된 경우는 정확성이 좀 떨어지기 때문에, 폴더 이름 순이 더 정확하겠네요

for /f "skip=30 tokens=*" %%a in ('dir /ad /b /o-n "E:\Backup\BD_DATA_*"') do rd /q /s "E:\Backup\%%a"

폴더가 어떤 순서로 나오는지만 확인했습니다

skip 숫자에 따라서 건너뛰게 됩니다

이번에 새로 작성한 코드 입니다. 이곳저곳에서 보고 작성하였는데 

이야기가 suk 님의 코드내용을 사용하기 좋은 내용이었습니다. 우선 이야기를 하자면 데이터 백업을 한 후 마지막 날의 폴더를 백업 폴더에서

이름을 변경하여 보관을 한다고 합니다. 그래서 날짜로 해버리면 큰 문제가 생겨버리는 일이 있더군요. 

그래서 만든것이 TXT 파일을 하나 만들어서 매번 백업을 하면 주소를 리스트업을 해 놓고. 백업한 TXT 파일이 30라인이 넘어버리면

첫 라인을 읽어 지우고 해당 문구에 맞는 폴더를 삭제하는 방식으로 하였습니다. ㅠㅠ;; 

::::::::: 일정 기간 지난 백업 폴더 삭제 ::::::::::
:ReDelete
for /F %%i in ('TYPE "%BACKUP_P%\backup_list.txt" ^| find /C /V ""') do set JUST_RATE=%%i

if %JUST_RATE% lss %DELETE_RATE% GOTO EndDelete

set /P DELETE_PATH=< %BACKUP_P%\backup_list.txt
rmdir /S /Q %DELETE_PATH%
echo %SD% : [%DELETE_PATH%] 오래된 백업 제거 완료>> %BACKUP_P%\complete.txt
findstr /l /v /i /c:"%DELETE_PATH%" %BACKUP_P%\backup_list.txt> %BACKUP_P%\backup_list_old.txt
timeout /t 1 > nul
del "%BACKUP_P%\backup_list.txt"
move %BACKUP_P%\backup_list_old.txt %BACKUP_P%\backup_list.txt

GOTO ReDelete

:EndDelete

지금 작성해서 테스트는 잘 되는편인데 더 테스트를 해봐야할 듯 하지만 순서대로 본다면. 

처음 for 가 저장되어진 리스트를 확인을 한 후 변수 JUST_RATE에 넣어주고. 

IF 로 정해놓은 수보다 적으면 GOTO 로 넘어가고. 아니면. 

(여기에 goto 문으로 넘긴것이 ( ) 안에 넣어버리니 변수가 동작을 안하더군요 ㅠㅠ; 나만 그런가? 에휴)

set /p 로 첫 문장을 변수로 읽어와 해당 폴더를 지우고. TXT 파일에 저장한 후

findstr로 첫 문장 링크를 제외한 텍스트를 old파일로 저장하고 

한박자 쉰 후

리스트 파일을 지우고 old 파일을 리스트 파일로 변환 ( 이 때 처음 한부부을 지운것이 저장되죠. )

이렇게 되어버리니 가령 d:\backup\backup_21001_1 경우.

d:\backup\backup_21001_1

d:\backup\backup_21001_10

d:\backup\backup_21001_11

d:\backup\backup_21001_12

이렇게 위와 같은 부분을 backup_list.txt 에서 다 삭제해 버리더군요 ㅠㅠ;;; 저럴 경우는 없고 날짜별로 될 것이기때문에 별 문제 없다고

생각되지만. 우선 기록차 댓글로 해당 내용을 작성해 둡니다. 

아참 그리고 저기 for 문 안에 왜 TYPE가 들어가는지도 모르는 수준입니다.. ㅠㅠ;; 그냥 막 복사하고 되네 정도니.. 너그러이 바주십시오. 에휴..