윈 도 우 USB에서 win7 사용하기
2010.10.31 10:06
스누피님의 'USB에 win7 설치하기'나
우금티님의 snapshot.exe 혹은 Hyper-V에 설치한 이미지를 이용하는 방법이 있지만
약간 다르게 USB에서 win7 사용하는 방법에 관한 글이 있어서 소개합니다.
원문링크: https://www.boot-land.net/forums/index.php?s=bb22e75502f16ddc5909e181bf273a8a&showtopic=9196
위 글에는 USB 디스크를 직접 사용하는 방법과 VHD를 이용하는 방법 두 가지를 설명하는 데 원리는 같습니다.
이 글에서는 제가 테스트해 본 VHD를 이용한 방법에 관해서만 소개합니다.
1. 하드디스크에 VHD를 만들어 win7을 설치합니다.( 기존에 VHD를 만들어 사용하신다면 그대로 사용하셔도 됩니다.)
2. VHD에 설치한 win7에서 usbbootfix.bat 를 실행한 후
다른 운영체제나 PE로 부팅하여 VHD를 USB에 복사합니다.
3. USB의 파티션에 활성( Active)을 걸어 줍니다.
4. USB안의 VHD를 연결( attach)해서 다음 명령으로 USB에 부팅파일을 만들어 줍니다.
bcdboot.exe k:\windows /l ko-kr /s j:
-? k: 는 VHD 드라이브 문자이고 j: 는 USB의 드라이브 문자입니다.
끝입니다. USB로 부팅하여 테스트 합니다.
<usbbootfix.bat 의 내용>
----------------------------------------------------------------------------------------------------------------
@echo off
if "%1"=="fix" goto :fix
rem -- install task
copy /y "%~f0" "%SystemRoot%\system32\usbbootfix.bat"
SCHTASKS /Create /RU SYSTEM /SC ONEVENT /MO "*[System[Provider[@Name='Microsoft-Windows-UserPnp'] and EventID=20003]]" /EC System /TN USBBootFix /TR "'%SystemRoot%\system32\usbbootfix.bat' fix" /F
rem -- apply other settings
reg add HKLM\SYSTEM\CurrentControlSet\services\pciide /v Start /t REG_DWORD /d 0x0 /f
reg add HKLM\SYSTEM\CurrentControlSet\services\msahci /v Start /t REG_DWORD /d 0x0 /f
reg add HKLM\SYSTEM\CurrentControlSet\services\intelide /v Start /t REG_DWORD /d 0x0 /f
reg add HKLM\SYSTEM\CurrentControlSet\services\viaide /v Start /t REG_DWORD /d 0x0 /f
rem -- run :fix once after install
:fix
call :fixservice usbehci "Boot Bus Extender"
call :fixservice usbohci "Boot Bus Extender"
call :fixservice usbuhci "Boot Bus Extender"
call :fixservice usbhub "System Bus Extender"
call :fixservice usbstor "SCSI miniport"
goto :eof
:fixservice
setlocal
set Start=
set Group=
for /f "skip=2 tokens=1,2,*" %%I in ('reg query HKLM\SYSTEM\CurrentControlSet\services\%~1') do (
if "%%I"=="Start" set Start=%%K
if "%%I"=="Group" set Group=%%K
)
if not "%Start%"=="0x0" reg add HKLM\SYSTEM\CurrentControlSet\services\%~1 /v Start /t REG_DWORD /d 0x0 /f
if not "%Group%"=="%~2" reg add HKLM\SYSTEM\CurrentControlSet\services\%~1 /v Group /t REG_SZ /d "%~2" /f
endlocal
goto :eof
----------------------------------------------------------------------------------------------------------------
주요 내용은
레지스트리에 등록된 하드 디스크 컨트롤러에 관한 서비스 값 중에서 'Start' 값을 0 으로 변경하고
USB에 관련된 서비스 값 중에서 'Start'와 'Group' 값을 0과 'Boot....'으로 변경한 뒤
EventID=20003( 서비스 설치) 가 생기면 위 배치 파일중 USB에 관련된 명령을 실행하게끔
작업 스케줄러에 등록하는 내용입니다.
드라이버를 설치하게 되면
HKLM\SYSTEM\CurrentControlSet\services와 기타 경로에 드라이버 정보를 등록하게 되는데
윈도우가 부팅하면서 이 곳의 레지스트리를 읽어서 드라이버를 로드하는 것 같습니다.
'Start' 값데이타가 0 인 드라이버는 부팅에 필요한 드라이버라는 뜻입니다.
USB 디스크 드라이버의 'Start' 기본값은 3 입니다.
'Group' 값 또한 구체적으로 로딩순서를 정하는 값인데
HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\ServiceGroupOrder 에 로딩순서대로
나열한 'Group' 값이 있습니다.
5. USB에 설치된 win7을 다른 컴퓨터에서 사용하려면 사용할 컴퓨터의 하드 디스크 컨트롤러 드라이버의
'Start' 값을 0 으로 변경한 뒤에 사용합니다.
어떤 드라이버인지 확실히 모를 경우 StorageBootStart.bat 를 실행한 뒤 종료한 다음 사용합니다.
StorageBootStart.bat 는 win7 에 미리 설치된 모든 하드 디스크 컨트롤러 드라이버의 'Start' 값을 0으로 변경시킵니다.
번호 | 제목 | 글쓴이 | 조회 | 추천 | 등록일 |
---|---|---|---|---|---|
[공지] | 강좌 작성간 참고해주세요 | gooddew | - | - | - |
1904 | 윈 도 우| 며느리도 몰랐다 예약 파티션 없이 설치하기 [26] | gooddew | 15327 | 0 | 03-11 |
1903 | 윈 도 우| 윈도우7에서 USB 키보드 인식 못할 경우 해결책 | 보로미르 | 22078 | 0 | 08-30 |
1902 | 윈 도 우| 혹시 내 컴퓨터도 좀비 PC?! 좀비 PC 확인법!! [10] |
|
15740 | 0 | 08-30 |
1901 | 윈 도 우| 노트북 x2300 win7 드라이버 잡기 |
|
8937 | 0 | 08-30 |
1900 | 윈 도 우| Driverpacks 로 MassStorage통합시 주의할점 [1] | 파워레이드 | 11658 | 0 | 09-01 |
1899 | 윈 도 우| 오해) 프로세스 사용계획 [5] |
|
10013 | 0 | 09-06 |
1898 | 윈 도 우| 윈도우10 종료 문제 [5] | 신영통 | 4720 | 0 | 04-08 |
1897 | 윈 도 우| win 7 설치 및 부팅 시 Cannot boot from CD - Code: 5 에러 [3] |
|
10286 | 0 | 09-24 |
1896 | 윈 도 우| Windows 7에 추가된 Meiryo UI 를 Segoe UI 일본어 글꼴로 ... [2] |
|
15676 | 0 | 10-06 |
1895 | 윈 도 우| PCI/USB WLAN의 Win7 에서 ADhoc 이 실패할 경우 사용법 [3] | Andrei Sak | 11692 | 0 | 10-03 |
1894 | 윈 도 우| 윈도우7 64 비트에서 게임이 약간씩 버벅일때 해결법-허접팁 [12] | 회탈리카 | 15447 | 0 | 10-04 |
1893 | 윈 도 우| LG X140 넷북 최적화관련 [2] | 이병찬 | 12060 | 0 | 10-10 |
» | 윈 도 우| USB에서 win7 사용하기 [2] |
|
13448 | 0 | 10-31 |
1891 | 윈 도 우| usb부팅 윈7 티니버전외 라이트버전 [2] |
|
13233 | 0 | 12-05 |
1890 | 윈 도 우| 해적, 독립의 길로 가다 [26] | 우금티 | 12862 | 0 | 12-02 |
1889 | 윈 도 우| 인터넷 익스플로러 9 플랫폼 프리뷰 6에 GUI 입히기 [4] |
|
34176 | 0 | 11-15 |
1888 | 윈 도 우| 간편한 원격관리툴 입니다. [10] | Andrei Sak | 9560 | 0 | 11-20 |
1887 | 윈 도 우| 윈도우7 인터넷 끊김현상 [24] |
|
24844 | 0 | 11-30 |
1886 | 윈 도 우| 디스플레이 드라이버가 응답을 중지하고 복구됨 [16] |
|
35514 | 0 | 11-26 |
1885 | 윈 도 우| 하드디스크에 PE 설치하기 [2] | 조르빈 | 20341 | 0 | 03-20 |
귀한 정보와 좋은 강좌,,,
고맙습니다.