소프트웨어 배치파일 문의드립니다 (파일 갯수 구하기)

하나의 FOR 명령 안에 여러개의 명령이 수행되게 만드시려면, DO 다음에 수행할 명령들을 괄호로 묶어주시면 됩니다.

set count=0

for %%a in (*.exe) do (

    start .... (설치명령)

    set /a count+=1

    echo exe is installed. (!count! of 100)

)

지난 질문 https://windowsforum.kr/qna/14667111 에 연결되는 것 같은데요

제가 그 때 올린 답변에 연결합니다

저 같은 경우는 전체 파일 갯수부터 계산하고, 카운트를 1개씩 올립니다

bat 파일 내용입니다.

@echo off

SETLOCAL ENABLEDELAYEDEXPANSION

cd /d %~dp0

for %%a in (*.exe) do set /a all+=1

echo.

for %%a in (*.exe) do set /a count+=1& echo %%a is being installed...^(!count! of %all%^)& start /wait %%a /passive /norestart & echo %%a is installed successfully^^! ^(!count! of %all%^)& echo.

pause

테스트하기에 적당한 exe 파일이 없어서 exe 설치 부분은 echo 처리했습니다.

실제 설치를 해야 하기 때문에 본문에는 echo를 뺐습니다

& 붙여서 전체를 1줄로 하는 것이 길어서 보기 불편하시면 ( )로 감싸서 & 를 지우시면 됩니다

exe 파일에 띄어쓰기가 된 경우를 감안하여 " "으로 감쌌습니다

@echo off

cd /d %~dp0

SETLOCAL ENABLEDELAYEDEXPANSION

for %%a in (*.exe) do set /a all+=1

echo.

for %%a in (*.exe) do (

set /a count+=1

echo "%%a" is being installed...^(!count! of %all%^)

start /wait "%%a" /passive /norestart

echo "%%a" is installed successfully^^! ^(!count! of %all%^)

echo.

)

pause

start /wait image.png /passive /norestart

이렇게 그림파일(.png)로 해보면 그림이 열리네요

start /wait "image.png" /passive /norestart

쌍따옴표로 감싸면 스위치가 틀렸다면서 오류나고요

뭐이런 이상한 경우가...