강좌 / 팁

윈 도 우 윈도우10 RS 자동최적화 bat(배치파일)

2017.09.16 14:41

제로데이 조회:10582 추천:14

Notice.bat


1. 원드라이브 삭제

2. 윈도우 개인정보 전송 차단

3. 윈도우 초기시작시 앱 자동설치 차단

 

3개의 내용을 하나로 합친거뿐입니다.

일일히 최적화 하시는 분들도 계실까봐 올려봅니다.

 

자동앱설치 막기는 윈도우10부터는 초기 포맷설치시 자동으로 앱들을 설치하길래 블로그 참조해서 넣었습니다.

 


 

출처 

https://github.com/TERRAOperative/OneDrive-Uninstaller/blob/master/OneDrive%20Uninstaller%20v1.2.bat

http://pcgeek.kr/index.php?mid=review&page=14&listStyle=gallery&document_srl=241973

http://slic.tistory.com/1200

 

 


 

@echo OFF

@REM 컬러 텍스트에 대한 변수 설정
SETLOCAL EnableDelayedExpansion
for /F "tokens=1,2 delims=#" %%a in ('"prompt #$H#$E# & echo on & for %%b in (1) do     rem"') do (
  set "DEL=%%a"
)

   echo ------Windows 10 RS2 원드라이브+개인정보전송+자동앱설치 차단------
   echo.
   
@rem 관리자권한 확인하는 코드
NET SESSION >nul 2>&1
IF %ERRORLEVEL% EQU 0 (


   echo        Administrator Privileges Detected!
   echo.
) ELSE (

   echo.
   call :colorEcho 0C "########### ERROR - ADMINISTRATOR PRIVILEGES REQUIRED #############"
   echo.
   call :colorEcho 0C "#                                                                 #"
   echo.
   call :colorEcho 0C "#"
   call :colorEcho 07 "    This script must be run as administrator to work properly."
   call :colorEcho 0C "    #"
   echo.
   call :colorEcho 0C "#"
   call :colorEcho 07 "    If you're seeing this after clicking on a start menu icon,"
   call :colorEcho 0C "   #"
   echo.
   call :colorEcho 0C "#"
   call :colorEcho 07 "  then right click on the file and select 'Run As Administrator'"
   call :colorEcho 0C " #"
   echo.
   call :colorEcho 0C "#                                                                 #"
   echo.
   call :colorEcho 0C "###################################################################"
   echo.
   echo.

   PAUSE
   EXIT /B 1
)

   echo -----------------------------------------------
   call :colorEcho 0C "                    WARNING"
   echo.
   call :colorEcho 0C "  This script will completely and permanently"
   echo.
   call :colorEcho 0C "      remove OneDrive from your computer."
   echo.
   call :colorEcho 0C "        Make sure all OneDrive documents"   
   echo.
   call :colorEcho 0C "       that are stored locally are fully"
   echo.
   call :colorEcho 0C "          backed up before proceeding."   
   echo.
   call :colorEcho 0C "          문제가 생기더라도 본인 책임입니다."   
   echo.
   echo -----------------------------------------------
   echo.

   SET /P M=  Press 'Y' to continue or any other key to exit. 
    if %M% ==Y goto PROCESSKILL
    if %M% ==y goto PROCESSKILL

   EXIT /B 1


@rem Terminate any OneDrive process
:PROCESSKILL
   echo.
   echo Terminating OneDrive process.
   
taskkill /f /im OneDrive.exe


@rem Detect if OS is 32 or 64 bit
reg Query "HKLM\Hardware\Description\System\CentralProcessor\0" | find /i "x86" > NUL && set OS=32BIT || set OS=64BIT

if %OS%==32BIT GOTO 32BIT
if %OS%==64BIT GOTO 64BIT


@rem Uninstall OneDrive app
:32BIT
   echo.
   echo This is a 32-bit operating system.
   echo Removing OneDrive setup files.
   
%SystemRoot%\System32\OneDriveSetup.exe /uninstall
GOTO CLEAN

:64BIT
   echo.
   echo This is a 64-bit operating system.
   echo Removing OneDrive setup files.
   
%SystemRoot%\SysWOW64\OneDriveSetup.exe /uninstall
GOTO CLEAN


@rem Clean and remove OneDrive remnants
:CLEAN
   echo.
   echo Removing remaining OneDrive folders.
   
   rd "%UserProfile%\OneDrive" /Q /S
   rd "%LocalAppData%\Microsoft\OneDrive" /Q /S
   rd "%ProgramData%\Microsoft OneDrive" /Q /S
   rd "C:\OneDriveTemp" /Q /S
   
   echo.
   call :colorEcho 0C "If you see 'access denied' errors here, reboot and run this batch file again."
   echo.

@rem Delete and remove OneDrive in file explorer folder tree registry key
   echo.
   echo Removing OneDrive registry keys.
   
   IF EXIST "HKEY_CLASSES_ROOT\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}" REG Delete "HKEY_CLASSES_ROOT\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}" /f
   IF EXIST "HKEY_CLASSES_ROOT\Wow6432Node\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}" REG Delete "HKEY_CLASSES_ROOT\Wow6432Node\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}" /f
   REG ADD "HKEY_CLASSES_ROOT\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}" /v System.IsPinnedToNameSpaceTree /d "0" /t REG_DWORD /f
   
   echo.
   echo OneDrive Uninstall and cleaning completed.
   echo.


echo.
echo 불필요한 스케줄러 끄기...
echo.


echo.
echo Microsoft Compatibility Appraiser
echo - MS 사용자 환경 개선 프로그램에 옵트인(opt in)한 경우 프로그램 원격 분석 정보를 수집합니다.

schtasks.exe /Change /TN "\Microsoft\Windows\Application Experience\Microsoft Compatibility Appraiser" /Disable


echo.
echo ProgramDataUpdater
echo - MS 사용자 환경 개선 프로그램에 설정된 경우 프로그램 원격 분석 정보를 수집합니다.

schtasks.exe /Change /TN "\Microsoft\Windows\Application Experience\ProgramDataUpdater" /Disable


echo.
echo StartupAppTask
echo - 시작 항목을 검색하고 시작 항목이 너무 많을 경우 사용자에게 알림을 표시합니다.

schtasks.exe /Change /TN "\Microsoft\Windows\Application Experience\StartupAppTask" /Disable


echo.
echo Consolidator
echo - Windows 사용자 환경 개선 프로그램에 참여하기로 동의한 경우 이 작업은 사용 데이터를 보냅니다.

schtasks.exe /Change /TN "\Microsoft\Windows\Customer Experience Improvement Program\Consolidator" /Disable


echo.
echo KernelCeipTask
echo - 커널 CEIP(사용자 환경 개선 프로그램) 작업은 시스템에 대한 추가 정보를 수집하고 이 데이터를 보냅니다.

schtasks.exe /Change /TN "\Microsoft\Windows\Customer Experience Improvement Program\KernelCeipTask" /Disable


echo.
echo UsbCeip
echo - USB CEIP(사용자 환경 개선 프로그램) 작업은 사용자 컴퓨터에 대해 USB(범용 직렬 버스) 관련 정보를 수집.

schtasks.exe /Change /TN "\Microsoft\Windows\Customer Experience Improvement Program\UsbCeip" /Disable


echo.
echo QueueReporting
echo - 진행할 Windows 오류 보고 작업에서 보고서를 큐에 넣었습니다.

schtasks.exe /Change /TN "\Microsoft\Windows\Windows Error Reporting\QueueReporting" /Disable


echo.
echo.
echo 개인정보 보호...
echo.


echo.
echo AllowTelemetry
echo - 윈도우에서 피드백을 통해 개인정보가 보내지는 것을 차단한다.

powershell.exe -command "Get-Service DiagTrack | Set-Service -StartupType Disabled"
powershell.exe -command "Get-Service dmwappushservice | Set-Service -StartupType Disabled"
reg add HKLM\SOFTWARE\Policies\Microsoft\Windows\DataCollection\ /v AllowTelemetry /t REG_DWORD /d 0 /f
:: reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\DataCollection" /v "AllowTelemetry" /t REG_DWORD /d "0" /f


echo.
echo NumberOfSIUFInPeriod
echo - 윈도우에서 내 피드백 요청 안함.

reg add "HKCU\SOFTWARE\Microsoft\Siuf\Rules" /v "NumberOfSIUFInPeriod" /t REG_DWORD /d "0" /f
reg delete "HKCU\SOFTWARE\Microsoft\Siuf\Rules" /v "PeriodInNanoSeconds" /f

echo.
echo Adverstising ID
echo - 앱에서 광고 ID를 사용하여 광고를 표시하는것을 끄기

reg add "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\AdvertisingInfo" /v "Enabled" /t REG_DWORD /d "0" /f
reg delete "HKCU\SOFTWARE\Microsoft\Windows\CurrentVersion\AdvertisingInfo" /v "id" /f
:: reg add "HKLM\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\AdvertisingInfo" /v "Enabled" /t REG_DWORD /d "0" /f
:: reg delete "HKLM\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\AdvertisingInfo" /v "id" /f


echo.
echo HttpAcceptLanguageOptOut
echo - 웹에서 내 언어 목록에 액세스 끄기

reg add "HKCU\Control Panel\International\User Profile" /v "HttpAcceptLanguageOptOut" /t REG_DWORD /d "1" /f


:: Send Miccrosoft info about how ... (내 쓰기 방법에 대한 정보 보냄... Win10 RS2에서 없어짐)
:: reg add "HKCU\SOFTWARE\Microsoft\Input\TIPC" /v "Enabled" /t REG_DWORD /d "0" /f


echo.
echo DisableThirdPartySuggestions
echo - 윈도우10 자동으로 앱설치되는거 막기

reg add "HKCU\Software\Policies\Microsoft\Windows\CloudContent" /v "DisableWindowsSpotlightFeatures" /t REG_DWORD /d "1" /f


echo.
echo DisableThirdPartySuggestions
echo - 윈도우10 자동으로 앱설치되는거 막기

reg add "HKCU\Software\Policies\Microsoft\Windows\CloudContent" /v "DisableThirdPartySuggestions" /t REG_DWORD /d "1" /f
echo.
echo.

   PAUSE
   echo 고생하셨습니다, 만약 제대로 되지 않았다면 재부팅후 다시 실행해주세요....
   PING -n 5 127.0.0.1>nul
   EXIT /B 1

   
@rem Settings for text colour

:colorEcho
echo off
<nul set /p ".=%DEL%" > "%~2"
findstr /v /a:%1 /R "^$" "%~2" nul
del "%~2" > nul 2>&1i

번호 제목 글쓴이 조회 추천 등록일
[공지] 강좌 작성간 참고해주세요 gooddew - - -
3229 모 바 일| (2차강좌) GalaxyNote8 에서 utorent 설정 및 토렌트파일 ... murimgasa 2145 1 09-18
3228 모 바 일| 스마트폰 utorrent 사용법-스마트폰의 모바일 utorrent에서... murimgasa 3688 1 09-16
3227 모 바 일| *Kinemaster강좌. 동영상에서 음악만 추출하는 방법, murimgasa 1185 1 09-16
» 윈 도 우| 윈도우10 RS 자동최적화 bat(배치파일) [20] 제로데이 10582 14 09-16
3225 모 바 일| 휴대폰 용량 확보하기 [11] 오후9시7분 4178 2 09-15
3224 소프트웨어| [수정]PE에서 Trueimage/Backupper 로그 유지 [8] 히이이잌 1798 3 09-15
3223 모 바 일| 스마트폰 글꼴 바꾸기,서체 변경하는 방법 강좌 murimgasa 1844 1 09-14
3222 모 바 일| 스마트폰에서 한자(漢字) 입력 방법-漢字 입력 方法 說明 murimgasa 1993 1 09-14
3221 소프트웨어| 우리가 모르는 카톡의 숨겨진 기능 Top3 murimgasa 3867 2 09-14
3220 하드웨어| PE 드라이버를 준비하는 Tip [8] 집앞의_큰 4381 7 09-02
3219 윈 도 우| 장치관리자 에서 WAN Miniport 삭제방법 [5] 우주선 6892 5 08-31
3218 소프트웨어| Kinemaster에서 동영상 배경을 투명하게하는 크로마키(Chro... murimgasa 1370 2 08-30
3217 소프트웨어| *Kinemaster강좌 , 동영상에서 음악만 추출하는 방법,*Kine... murimgasa 1707 2 08-26
3216 소프트웨어| 크롬(chrome) 자간 버그 [7] 배불러 2925 1 08-25
3215 소프트웨어| Adobe Premiere강좌 화면떨림 보정(Warp Stabilizer)하는 방법 [1] murimgasa 1315 1 08-25
3214 소프트웨어| Adobe Premiere CS6 강좌 유용한 팀Tip 몇가지 -복사단축키... [1] murimgasa 1175 1 08-25
3213 소프트웨어| Adobe Premiere에서 스마트폰용 동영상 제작하는 방법 강좌 murimgasa 1089 0 08-23
3212 소프트웨어| Photoshop 강좌 - 입체적인 글자 만들기_ 바탕화면에 글자 ... [2] murimgasa 1649 1 08-23
3211 소프트웨어| * 스마트폰의 동영상 제작  앱 강자인 키네마스터 자막 쉽... murimgasa 1326 1 08-22
3210 소프트웨어| Adobe Premiere 강좌 Corner Pin, 동영상 화면크기 위치 조... [1] murimgasa 1458 2 08-20
XE1.11.6 Layout1.4.8